Примерно так:

CREATE TABLE #Hierarchy
(
ID int NOT NULL PRIMARY KEY,
ParentID int NULL,
IsFolder int NOT NULL,
Descr nvarchar(100) NOT NULL
)

Insert Into #Hierarchy
VALUES(1,NULL,1,'Folder1')
Insert Into #Hierarchy
VALUES(2,NULL,1,'Folder2')
Insert Into #Hierarchy
VALUES(3,NULL,1,'Folder3')
Insert Into #Hierarchy
VALUES(4,NULL,1,'Folder4')

Insert Into #Hierarchy
VALUES(11,1,1,'Folder11')
Insert Into #Hierarchy
VALUES(12,1,1,'Folder12')
Insert Into #Hierarchy
VALUES(110,11,0,'Item110')
Insert Into #Hierarchy
VALUES(120,12,0,'Item120')

Insert Into #Hierarchy
VALUES(121,12,1,'Folder121')
Insert Into #Hierarchy
VALUES(1210,121,0,'Item1210')

/******************************************************************
Выбрать элементы, принадлежащие заданной группе.
ID Группы поместить в переменную @ID
Поместить туда NULL если требуется выбрать все элементы справочника
******************************************************************/

DECLARE @ID int
Set @ID=NULL

DECLARE @Level int
Set @Level=1

create table #tmp1(id int not null,[level] int not null, path nvarchar(3000) not null)
If @ID Is NULL
Insert Into #tmp1
Select
id,
@level,
descr
From
#Hierarchy
WHERE
ParentID Is NULL
ELSE
Insert Into #tmp1
Select
id,
@level,
descr
From
#Hierarchy
WHERE
ParentID=@ID

WHILE @@rowcount>0
BEGIN
Set @level=@level+1
Insert Into #tmp1
Select
h.id,
@level,
t.path+CHAR(0)+h.descr
From
#tmp1 t
inner join #Hierarchy h
on t.id=h.Parentid and t.[level]=@level-1
END

/*****************************************************
Вывод результатов в иерархическом виде
*****************************************************/
Select
t.id,
SPACE((t.[level]-1)*5)+h.Descr,
h.IsFolder
From
#tmp1 t
inner join #Hierarchy h
on t.id=h.id
Order By
t.path
drop table #tmp1

/**********************************************************
Определить, принадлежит ли заданный элемент @Item
заданной группе @Folder
**********************************************************/
DECLARE @Item int, @Folder int
Set @Item=120
Set @Folder=1

DECLARE @Folder1 int

Select @Folder1=ParentID from #Hierarchy where ID=@Item

WHILE @Folder1 Is Not NULL
BEGIN
If @Folder1=@Folder
BEGIN
Select @Item As Item,'содержится в папке',@Folder
BREAK
END
Select @Folder1=ParentID from #Hierarchy where ID=@Folder1
END

If @Folder1 Is NULL
Select @Item As Item,'не содержится в папке',@Folder

drop table #Hierarchy

С уважением,
Александр Степанов