declare @t1 table(ID int, Parent_ID int, Name varchar(50))
insert into @t1 values
(1, null, 'Бюджетирую затраты в поездке'), (2,1,'экскурсии'),(3,2,'экскурсию к памятнику'),(4,1,'жрачку')

declare @t2 table(t1ID int, TotalSum money)
insert into @t2 values
(1,1000),(2,400),(3,150),(4,300)

;with cte as (
	select 
		t1.ID
		,t1.Parent_ID
		,t1.Name
		,t2.TotalSum
		,tt2.TotalSum as Parent_TotalSum 
		,sum(t2.TotalSum)over(partition by t1.Parent_ID) as Level_TotalSum
		,row_number()over(partition by t1.Parent_ID order by t1.ID) as Level_num
		,max(t1.ID)over(partition by t1.Parent_ID) as Max_Level_ID
		,count(t1.ID)over(partition by t1.Parent_ID) as Level_ID_count
	from @t1 t1 inner join @t2 t2 on t1.ID = t2.t1ID
	left join @t2 tt2 on t1.Parent_ID = tt2.t1ID
),
cte1 as (
	select 
		*
		,Num		=cast(Level_num as varchar(max))
		,ParentNum	=cast('' as varchar(max)) 
	from cte
	where Parent_ID is null

	union all

	select 
		cte.*
		,Num		=cte1.Num+'.'+cast(cte.Level_num as varchar(max))
		,ParentNum	=cte1.Num
	from cte inner join cte1 on cte.Parent_ID = cte1.ID	
)

select
	ID
	,Parent_ID
	,Num
	,Name
	,TotalSum
from cte1 

union all

select
	null
	,Parent_ID
	,ParentNum+'.'+cast(Level_ID_count+1 as varchar)
	,Name		='Другое'
	,TotalSum	=Parent_TotalSum - Level_TotalSum
from cte1 
where	Max_Level_ID = ID
	and Parent_TotalSum - Level_TotalSum <> 0

order by 3