Option Compare Database
Option Explicit

Private WithEvents mtbo As TextBox
Private mintIndex As Integer
Private mmtbsParent As clsMyTextBoxes

Public Property Get TextBoxControl() As TextBox
    Set TextBoxControl = mtbo
End Property
Public Property Set TextBoxControl(ByRef tboNewValue As TextBox)
    Set mtbo = tboNewValue
    mtbo.AfterUpdate = "[Event Procedure]"
End Property

Public Property Get Index() As Integer
    Index = mintIndex
End Property
Public Property Let Index(ByVal intNewValue As Integer)
    mintIndex = intNewValue
End Property

Public Property Get Parent() As Object
    Set Parent = mmtbsParent
End Property
Public Property Set Parent(ByRef objNewValue As Object)
    Set mmtbsParent = objNewValue
End Property

Private Sub mtbo_AfterUpdate()
    mmtbsParent.FireEvent mintIndex
End Sub

Option Compare Database
Option Explicit

Private mctbos As Collection
Public Event AnyTextBoxAfterUpdate(intIndex As Integer)

Private Sub Class_Initialize()
    Set mctbos = New Collection
End Sub

Public Sub AddMyTextBox(tbo As TextBox, intIndex As Integer)
    Dim mtb As clsMyTextBox
    Set mtb = New clsMyTextBox
    Set mtb.TextBoxControl = tbo
    mtb.Index = intIndex
    Set mtb.Parent = Me
    mctbos.Add mtb, Trim(Str(intIndex))
    Set mtb = Nothing
End Sub

Public Sub FireEvent(intIndex As Integer)
    RaiseEvent AnyTextBoxAfterUpdate(intIndex)
End Sub

Option Compare Database
Option Explicit

Private WithEvents mmtbs As clsMyTextBoxes

Private Sub Form_Load()
Dim ctl As Control
Dim i As Integer

Set mmtbs = New clsMyTextBoxes
i =  1 

For Each ctl In Me.Controls
    If TypeOf ctl Is TextBox Then
        mmtbs.AddMyTextBox ctl, i
        i = i +  1 
    End If
Next

End Sub

Private Sub mmtbs_AnyTextBoxAfterUpdate(intIndex As Integer)
    MsgBox intIndex
End Sub