Public Type TPrevValues
    lT01Val As Long
    lT01Date As Variant
    lT02Val As Long
    lT02Date As Variant
    lT03Val As Long
    lT03Date As Variant
End Type

Public Function GetPreviousValues(objForm As Form) As TPrevValues
Dim s$, vAdr, vID, vDate, i%
Dim rst As DAO.Recordset
    
On Error GoTo GetPreviousValues_Err
    If objForm!cbxАдрес.ListIndex = -1 Then GoTo GetPreviousValues_Bye
    
    vAdr = objForm!cbxАдрес 'ID Адреса
    vID = objForm!txtID     'ID Записи
    vDate = objForm!txtДата 'Дата Записи ...
    
    For i = 1 To 3
        s = "SELECT TOP 1 * FROM ЭлектроЭнергия" & _
        " WHERE Id<>" & Nz(vID, 0) & " AND Адрес=" & Nz(vAdr, 0) & _
        " AND Дата < " & Format$(Nz(vDate, 0), "\#mm\/dd\/yyyy\ hh:nn:ss#") & _
        " AND Nz([Т" & i & "])>0" & _
        " ORDER BY Дата DESC;"
        'AND Nz([Т1])+Nz([Т2])+Nz([Т3])>0
        'Debug.Print s
        Set rst = CurrentDb.OpenRecordset(s, dbOpenSnapshot)  'Только просмотр
        If rst.EOF = False Then
            With rst
                Select Case i
                Case 1
                    GetPreviousValues.lT01Val = Nz(!Т1, 0)
                    GetPreviousValues.lT01Date = !Дата
                Case 2
                    GetPreviousValues.lT02Val = Nz(!Т2, 0)
                    GetPreviousValues.lT02Date = !Дата
                Case 3
                    GetPreviousValues.lT03Val = Nz(!Т3, 0)
                    GetPreviousValues.lT03Date = !Дата
                End Select
            End With
        End If
    Next i
    
    
GetPreviousValues_Bye:
    On Error Resume Next
    Set rst = Nothing
    Err.Clear
    Exit Function
    
GetPreviousValues_Err:
    MsgBox "Error " & Err.Number & vbCrLf & Err.Description & vbCrLf & _
    "in Function [GetPreviousValues]" & vbCrLf & _
    "in Module []", vbCritical, "Error!"
    Resume GetPreviousValues_Bye
End Function