Public Function AddMyProp(myPropName As String, myPropValue) As Boolean
On Error GoTo Err_function
    CurrentProject.Properties.Add myPropName, myPropValue
    AddMyProp = True
Exit_Function:
    Exit Function

Err_function:
    funMsgBox Err.Description, vbInformation, "AddMyProp"
    Resume Exit_Function
End Function

Public Function funWritePropValue(myPropName As String, myPropValue) As Boolean
On Error GoTo Err_function

    CurrentProject.Properties(myPropName) = myPropValue
    funWritePropValue = True
Exit_Function:
    Exit Function
Err_function:
    Select Case Err.Number
        Case Is = 2455
            funWritePropValue = AddMyProp(myPropName, myPropValue)
        Case Else
            funMsgBox Err.Description, vbInformation, "funWritePropValue"
    End Select
    Resume Exit_Function
End Function

Public Function funReadPropValue(myPropName As String)
On Error GoTo Err_function

    funReadPropValue = CurrentProject.Properties(myPropName)
    
Exit_Function:
    Exit Function
Err_function:
    Select Case Err.Number
        Case Is = 2455
            AddMyProp myPropName, 0
            funReadPropValue = 0
        Case Else
            funMsgBox Err.Description, vbInformation, "funReadPropValue"
    End Select
    Resume Exit_Function
End Function