Option Compare Database
Option Explicit

Private Declare Function EnumWindows Lib "user32" (ByVal lpEnumFunc As Long, _
    ByVal lParam As Long) As Long

Private Declare Function EnumChildWindows _
    Lib "user32" (ByVal hWndParent As Long, ByVal lpEnumFunc As Long, ByVal lParam As Long) As Long

Private Declare Function GetWindowText _
    Lib "user32" _
    Alias "GetWindowTextA" (ByVal hWnd As Long, ByVal lpString As String, ByVal cch As Long) As Long

Private Declare Function GetWindowRect _
    Lib "user32" (ByVal hWnd As Long, lpRect As RECT) As Long

Private Declare Function FindWindowEx _
    Lib "user32" _
    Alias "FindWindowExA" (ByVal hWnd1 As Long, ByVal hWnd2 As Long, ByVal lpsz1 As String, ByVal lpsz2 As String) As Long

Private Declare Function FindWindow _
    Lib "user32" _
    Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long

Private Declare Function GetParent _
    Lib "user32" (ByVal hWnd As Long) As Long

' Store rectangle coordinates.
Public Type RECT
    Left As Long
    Top As Long
    Right As Long
    Bottom As Long
End Type

' Windows 95/98/NT4/2000 puts a 2-pixel
' border around the MDI client area, which
' doesn't get taken into account automatically.
' If you're using NT 3.51, you're on your own.
Private Const adhcBorderWidthX = 2
Private Const adhcBorderWidthY = 2

Private captionToFind As String ' not safe
Private currentCaption As String
Private foundHWND As Long

Public Function getChildByCaption(caption As String, Optional inApp As Application) As Long
    If inApp Is Nothing Then
        Set inApp = Application
    End If
    
    captionToFind = caption
    currentCaption = String(100, " ")
    foundHWND = 0
    
    EnumChildWindows inApp.hWndAccessApp, AddressOf EnumWindows_Seek, 1
    
    getChildByCaption = foundHWND
End Function

Private Function EnumWindows_Seek(ByVal hWnd As Long, ByVal lParam As Long) As Long
    Dim l As Long
    l = GetWindowText(hWnd, currentCaption, 100)

    If captionToFind <> Left(currentCaption, l) Then
        ' Return 1 to continue enumeration
        EnumWindows_Seek = 1
    Else
        foundHWND = hWnd
        EnumWindows_Seek = 0
        ' Return 0 to stop enumeration
    End If

End Function

Public Function GetRECT(hWnd As Long) As RECT

    ' modified : return RECT instead of write into byRef COORDS
    ' Fill in rct with the coordinates of the client area.
    ' Fill in rctWindow with coordinates of the window.

    ' From Access 2002 Desktop Developer's Handbook
    ' by Litwin, Getz, and Gunderloy (Sybex)
    ' Copyright 2001.  All rights reserved.
    
    On Error GoTo HandleErrors
    Dim hWndParent As Long
    Dim rctParent As RECT
    Dim rct As RECT

    ' Find the position of the window in question, in
    ' relation to its parent window (the Access desktop,
    ' the MDIClient window).
    hWndParent = GetParent(hWnd)

   ' Get the coordinates of the current window and its parent.
    Call GetWindowRect(hWnd, rct)

    ' Catch the case where the form is Popup (that is,
    ' its parent is NOT the Access main window.)  In that
    ' case, don't subtract off the coordinates of the
    ' Access MDIClient window.
    Select Case 1 'ReferenceType
        Case 0 'rtPopup
            ' No special calculations necessary.
        Case 1 'rtNormal
            ' Get the MDI Client window's coordinates.
            Call GetWindowRect(hWndParent, rctParent)
    
            ' Subtract off the left and top parent coordinates,
            ' since you need coordinates relative to the parent
            ' for the MoveWindow function call.
            ' Also, subtract off the small border of the
            ' MDI Client window that no one will admit to.
            With rct
                .Left = .Left - rctParent.Left - adhcBorderWidthX
                .Top = .Top - rctParent.Top - adhcBorderWidthY
                .Right = .Right - rctParent.Left - adhcBorderWidthX
                .Bottom = .Bottom - rctParent.Top - adhcBorderWidthY
            End With
    End Select
    
    GetRECT = rct

ExitHere:
    Exit Function

HandleErrors:
    Select Case Err.Number
        Case Else
            Debug.Print "FormInfo.GetCoords", Err.Number, Err.Description
    End Select
    Resume ExitHere
End Function