Public Function Get_File(lng_FileID As Long, Optional str_Destination As String, Optional str_FileName As String) As String
' extracts and saves file from attachment field
On Error GoTo ErrorHandler

Dim rst As DAO.Recordset
Dim rstA As DAO.Recordset
Dim str_SQL As String
Dim str_FullPath As String
Dim db as DAO.Database

Get_File = "Error"

Set db = CurrentDb

str_SQL = "SELECT tbl_SystemFiles.ID, tbl_SystemFiles.FileDescription, tbl_SystemFiles.ExportFileName, tbl_SystemFiles.FileLocation, tbl_SystemFiles.Attachments " _
& "FROM tbl_SystemFiles " _
& "WHERE (((tbl_SystemFiles.ID)=" & lng_FileID & "));"

Set rst = db.OpenRecordset(str_SQL, dbOpenSnapshot)

If rst.RecordCount > 0 Then

Set rstA = rst("Attachments").Value

If str_FileName = "" Then
str_FileName = rst!ExportFileName
End If

If str_Destination = "" Then
str_Destination = rst!FileLocation
End If

If Right(str_Destination, 1) = "\" Then
str_FullPath = str_Destination & str_FileName
Else
str_FullPath = str_Destination & "\" & str_FileName
End If

On Error Resume Next
Kill str_FullPath
MakeMultiDir str_Destination
rstA("FileData").SaveToFile str_FullPath

If err = 0 Then
Get_File = str_FileName
End If

On Error GoTo 0

End If

Exit_ErrorHandler:
On Error Resume Next
rst.Close
Set rst = Nothing
rstA.Close
Set rstA = Nothing
Exit Function
ErrorHandler:
Select Case err.Number
Case 70
MsgBox str_FullPath & " is currently in used. Please close the file and try again."
Case Else
gbl_DSS_Framework.DisplayUnhandledErrorMsgBox err, "bas_Get_File", "Get_File", Erl
End Select
Resume Exit_ErrorHandler
End Function