Option Compare Database
Option Explicit

Dim H(1 To 3) As Single ' Массив для хранения значений высоты поля в зависимости от числа строк.
                        ' Индекс элемента сответствует количеству строк.
                        ' Например, H(1)- высота поля в одну строку, H(2)- высота поля в две строки, и т.д.
                        ' В данном конкретном случае (для меню) должно хватить трех элементов.
                        ' Если нет - увеличить размерность массива
 
Private Sub Report_Open(Cancel As Integer)
 WizHook.Key = 51488399 ' Инициализация скрытого объекта WizHook (найдите о нем информацию на форуме, почитайте)
 
 H(1) = 0.608           ' Присвоение значений элементам массива.
 H(2) = 1.058           ' Значения получаем вручную в конструкторе отчета, для разного количества строк в поле.
 H(3) = 2.063           ' Можно было бы организовать и автоматическое определение (с помощью одной из функций Лебанса),
                        ' но это еще километры кода, а здесь можно и обойтись предварительными ручными операциями.
                        ' То есть, именно из-за этого стали ползти строки при другом шрифте.
                        ' Подставьте правильные значения, и все придет в норму.
End Sub

Private Sub Report_Close()
 WizHook.Key = 0        ' Отключение скрытого объекта WizHook при закрытии отчета.
End Sub

Private Sub ОбластьДанных_Format(Cancel As Integer, FormatCount As Integer)
 Dim K As Byte, _
     S As String
 Dim wzCch As Long, _
     wzMaxWidthCch As Long, _
     wzdx As Long, _
     wzdy As Long        ' Объявляем переменные, требующиеся для работы WizHook
 Стоимость_блюда.Top = 0 ' Переносим "блуждающее" поле вверх - чтобы не мешало менять высоту Области Данных
 Перевод_блюда.Top = 0   ' То же самое
 With F_Наименование_блюда
  S = Left(.Value, InStr(.Value, ". . . ") - 1) ' Выделяем "значимую" часть поля F_Наименования блюда
                                                ' (без хвостовых точек)
  WizHook.TwipsFromFont .FontName, .FontSize, .FontWeight, .FontItalic, .FontUnderline, _
                        wzCch, S, wzMaxWidthCch, wzdx, wzdy ' Работает WizHook
  K = wzdx \ .Width - ((wzdx Mod .Width) > 0) ' Получив от WizHook ширину текста
                                              ' при текущих характеристиках шрифта,
                                              ' и зная ширину поля, вычисляем количество строк.
  .Height = H(K) * 567                                             ' Задаем высоту поля F_Наименование_блюда,
                                                                   ' определяемую вычисленным количеством строк
  Section(0).Height = H(K) * 567                                   ' То же самое для Области Данных
  Стоимость_блюда.Top = Section(0).Height - Стоимость_блюда.Height ' Переносим поле Стоимость_блюда
                                                                   ' к последней строке Наименования
  Section(0).Height = Section(0).Height + Перевод_блюда.Height     ' Увеличиваем высоту Области Данных
                                                                   ' на высоту поля Перевод_блюда
  Перевод_блюда.Top = .Top + .Height                               ' Размещаем поле Перевод_блюда
                                                                   ' под полем F_Наименование_блюда
 End With
End Sub

=[Наименование_блюда] & IIf([Стоимость_блюда] Is Null;"";". . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . ")

  S = Left(.Value, InStr(.Value, ". . . ") - 1)

  If F_Наименование_блюда = Наименование_блюда Then
   S = .Value
  Else
   S = Left(.Value, InStr(.Value, ". . . ") - 1)
  End If