Function ListPK(tbl As String) As String
    'List primary keys for passed table.
    'Must reference ADOX library:
    'Microsoft ADO Ext. 2.8 for DDL and Security.

    Dim cat As New ADOX.Catalog
    Dim tblADOX As New ADOX.Table
    Dim idxADOX As New ADOX.Index
    Dim colADOX As New ADOX.Column
    cat.ActiveConnection = CurrentProject.AccessConnection
    On Error GoTo errHandler
    For Each tblADOX In cat.Tables
       If tblADOX.Name = tbl Then
          If tblADOX.Indexes.Count <> 0 Then
             For Each idxADOX In tblADOX.Indexes
                With idxADOX
                   If .PrimaryKey Then
                      For Each colADOX In .Columns
                         ListPK = colADOX.Name & ", " & ListPK
                      Next
                   End If
                End With
             Next
          End If
       End If
    Next
    If ListPK = "" Then 
       ListPK = "No primary key"
    Else
       ListPK = Left(ListPK, Len(ListPK) - 2)
    End If
    Set cat = Nothing  Set tblADOX = Nothing
    Set idxADOX = Nothing
    Set colADOX = Nothing
    Exit Function

    errHandler:  MsgBox Err.Number & ": " & Err.Description, vbOKOnly, _
    "Error"
    Set cat = Nothing
    Set tblADOX = Nothing
    Set idxADOX = Nothing
    Set colADOX = Nothing
End Function