Sub asskip()
Dim DB As DAO.Database, RSA As DAO.Recordset, RSW As DAO.Recordset
Dim b$, t&
  Set DB = CurrentDb
  DB.Execute "DELETE * FROM tabSkip"
  Set RSA = DB.OpenRecordset("SELECT * FROM Assay ORDER BY BHID, [FROM]", dbOpenSnapshot)
  Set RSW = DB.OpenRecordset("tabSkip", dbOpenDynaset)
  If Not RSA.EOF Then b = RSA!BHID - 1
  Do Until RSA.EOF
    If b = RSA!BHID Then
      If RSA!FROM > t Then
        RSW.AddNew
        RSW!BHID = b: RSW!FROM = t: RSW!To = RSA!FROM
        RSW.Update
      End If
    Else
      b = RSA!BHID
    End If
    t = RSA!To
    RSA.MoveNext
  Loop
  RSA.Close: Set RSA = Nothing
  RSW.Close: Set RSW = Nothing
  Set DB = Nothing
End Sub

Sub AddAssay()
Dim i&, j&, ar
  ar = Array(0, 5, 5, 6, 6, 8, 10, 15, 15, 20, 25, 30, 30, 36, 36, 40, 42, 45, 45, 50)
  CurrentDb.Execute "DELETE * FROM ASSAY"
  With CurrentDb.OpenRecordset("assay", dbOpenDynaset)
  For i = 1 To 10000
    For j = 0 To 19 Step 2
      .AddNew: !BHID = i: !FROM = ar(j): !To = ar(j + 1): .Update
    Next
  Next
  End With
End Sub

Sub timtest()
Dim t!, sq$
  t = Timer
  asskip
  Debug.Print "Процедура", Timer - t
  
'-----------------------------------------------------------
  
  sq = "SELECT Q1.BHID, Q1.[TO] As _FROM, Min(Q2.[FROM]) As _TO " & _
       "FROM " & _
       "(SELECT A1.BHID, A1.[TO] " & _
       "FROM ASSAY As A1 INNER JOIN ASSAY AS A2 ON A1.BHID=A2.BHID And A1.[TO] <= A2.[FROM] " & _
       "GROUP BY A1.BHID, A1.[TO] " & _
       "HAVING Min(A2.[FROM])<>A1.[TO]) As Q1 "
  sq = sq & "INNER JOIN " & _
      "(SELECT A1.BHID, A1.[FROM] " & _
      "FROM ASSAY As A1 INNER JOIN ASSAY AS A2 ON A1.BHID=A2.BHID And A1.[FROM] >= A2.[TO] " & _
      "GROUP BY A1.BHID, A1.[FROM] " & _
      "HAVING Max(A2.[TO])<>A1.[FROM]) As Q2 " & _
      "ON Q1.BHID=Q2.BHID And Q1.[TO]<=Q2.[FROM] " & _
      "GROUP BY Q1.BHID, Q1.[TO]"
  t = Timer
  CurrentDb.OpenRecordset(sq).MoveLast
  Debug.Print "-Практикант-", Timer - t
  
'-----------------------------------------------------------

  sq = "select t1.BHID, t1.[TO], t2.[FROM], iif(t1.[TO] < t2.[FROM], 'Пропуск', 'Перехлест') as Note_ " & _
       "from tmp as t1 " & _
       "inner join tmp as t2 " & _
       "on t1.BHID = t2.BHID " & _
       "  and t1.id + 1 = t2.id " & _
       "where t1.[TO] <> t2.[FROM]"
  t = Timer
  CurrentDb.OpenRecordset(sq).MoveLast
  Debug.Print "Akina-Rivkin", Timer - t
End Sub