Public Function SaveRecODBC(Frm As Form) As Boolean
    Dim Ctrl As Access.Control
    Dim Fld  As DAO.Field
    Dim E    As DAO.Error
    
    On Error GoTo ODBC_Error
    With Frm.RecordsetClone
    If Frm.Dirty = True Then
        If Frm.NewRecord = True Then
            .AddNew
            For Each Ctrl In Frm.Controls
                Select Case Ctrl.ControlType
                Case acTextBox, acComboBox, acListBox, acCheckBox
                    Select Case Left$(Ctrl.Properties("ControlSource").Value & "=", 1)
                    Case "="
                    Case Else
                        If IsNull(Ctrl.Value) = False Then
                            For Each Fld In .Fields
                                If Fld.Name = Ctrl.Properties("ControlSource").Value Then
                                    Fld.Value = Ctrl.Value
                                    Exit For
                                End If
                            Next Fld
                        End If
                    End Select
                End Select
            Next Ctrl
            .Update
        Else
            .Bookmark = Frm.Bookmark
            .Edit

            For Each Ctrl In Frm.Controls
                Select Case Ctrl.ControlType
                Case acTextBox, acComboBox, acListBox, acCheckBox
                    Select Case Left$(Ctrl.Properties("ControlSource").Value & "=", 1)
                    Case "="
                    Case Else
                        For Each Fld In .Fields
                            If Fld.Name = Ctrl.Properties("ControlSource").Value Then
                                If Fld.Value <> Ctrl.Value Or _
                                        IsNull(Fld.Value) <> IsNull(Ctrl.Value) Then
                                    Fld.Value = Ctrl.Value
                                End If
                                Exit For
                            End If
                        Next Fld
                    End Select
                End Select
            Next Ctrl
            .Update
        End If ' End If Frm.NewRecord
    End If ' End If Frm.Dirty
    End With
    SaveRecODBC = True

Exit_SaveRecODBCErr:
    Set Ctrl = Nothing
    Set Fld = Nothing
    Set E = Nothing
    Exit Function

ODBC_Error:
    Dim strTxt As String
    Dim strErr As String
    
    For Each E In DBEngine.Errors
        strTxt = E.Description
        If strTxt Like "*[[]SQL Server[]]*" Then
            strTxt = Mid$(strTxt, InStr(1, strTxt, "[SQL Server]") + 12)
            If strTxt Like "*([#]*" Then
                strTxt = Left$(strTxt, InStr(1, strTxt, "(#") - 1)
            End If
            ' Если уже имеется как минимум 1 текст ошибки на русском языке, то текст ошибки _
              на английском можно пропустить.
            If Len(strErr) = 0 Or E.Description Like "*[А-я]*" Then
                strErr = strErr & vbCrLf & strTxt
            End If
        End If
    Next E
    MsgBox Mid$(strErr, 3)
    SaveRecODBC = False
    Resume Exit_SaveRecODBCErr
End Function

Function BeforeUpdateOfForm(Optional Frm As Access.Form) As Integer
    If Frm Is Nothing Then Set Frm = Screen.ActiveForm
    
    ' Попробуем сохранить изменения.
    If SaveRecODBC(Frm) = True Then
        Frm.Undo
        ' Если текущая запись новая, то следует переходить на последную запись.
        If Frm.NewRecord = True Then
            DoCmd.GoToRecord acForm, Frm.Name, acLast
        End If
        BeforeUpdateOfForm = 0
    Else
        ' Елси не удалось сохранить изменения, то следует вернуть -1 для отмены _
          обновления.
        BeforeUpdateOfForm = -1
    End If
End Function