Function MsgBoxExt(Prompt As String, Optional Buttons As VbMsgBoxStyle = vbOKOnly, _\n        Optional Title, Optional ByVal SecondsToWait As Integer) As Integer\n    \' Аналог MsgBox с возможностью самовыключения.\n    \' Возвращает код нажатой клавиши или -1, если время ожидания исчерпано.\n    Dim wshShell As Object\n    \n    Set wshShell = VBA.CreateObject("WScript.Shell")\n    MsgBoxExt = wshShell.PopUp(Prompt, SecondsToWait, Title, Buttons)\nEnd Function

Private Declare Function MessageBoxW Lib "user32" ( _\n   ByVal hWnd As Long, ByVal lpText As String, _\n   ByVal lpCaption As String, ByVal wType As VbMsgBoxStyle) As VbMsgBoxResult\n\nSub Hello()\n MessageBoxW  0 , _\n             StrConv("!" & ChrW(&HFE8E) & ChrW(&HFE92) & ChrW(&HFEA3) & _\n                     ChrW(&HFEAE) & ChrW(&HFEE3), vbUnicode), _\n             StrConv("Мархаба!", vbUnicode), _\n             vbExclamation + vbMsgBoxRight + vbMsgBoxRtlReading\nEnd Sub

Private Sub SortACBtn_Click(ByVal Ctrl As Office.CommandBarButton, CancelDefault As Boolean)  
    On Error Resume Next
    'CancelDefault = True - если вместо сортировки своя процедура'  
    MsgBox "Сортировка по возрастанию "  
End Sub
 
Private Sub SortDeBtn_Click(ByVal Ctrl As Office.CommandBarButton, CancelDefault As Boolean)  
    MsgBox "Сортировка по Убыванию "  
End Sub
 
Private Sub Form_Load()  
    Set SortACBtn = CommandBars.FindControl(id:= 210 )  
    Set SortDeBtn = CommandBars.FindControl(id:= 211 )  
End Sub

Private Declare Function ShellAbout _
        Lib "shell32.dll" Alias "ShellAboutA" ( _
        ByVal hWnd As Long, _
        ByVal szApp As String, _
        ByVal szOtherStuff As String, _
        ByVal hIcon As Long) As Long

Private Sub ShowAbout()
    ShellAbout  0 &, "", "",  0 &
End Sub

Private Declare Function ShellAbout _
        Lib "shell32.dll" Alias "ShellAboutA" ( _
        ByVal hWnd As Long, _
        ByVal szApp As String, _
        ByVal szOtherStuff As String, _
        ByVal hIcon As Long) As Long

Private Sub ShowAbout()
    ShellAbout _
         0 &, _
        "Заголовок и 1-строка", _
        "Здесь напишем какой-нибудь текст, который будет " & _
            "выходить где-то в середине." & vbCrLf, _
         0 &
End Sub

Private Declare Function ShellAbout _
        Lib "shell32.dll" Alias "ShellAboutA" ( _
        ByVal hWnd As Long, _
        ByVal szApp As String, _
        ByVal szOtherStuff As String, _
        ByVal hIcon As Long) As Long
Private Declare Function LoadIcon _
        Lib "user32.dll" Alias "LoadIconA" ( _
        ByVal hInstance As Long, _
        ByVal lpIconName As Long) As Long

Private Sub ShowAbout()
    ShellAbout _
         0 &, _
        "Что это такое?", _
        "Test is test!" & vbCrLf, _
        LoadIcon( 0 &,  32514 &)
End Sub

' Объявляем модульные переменные для расширения текста в Textbox по ширине _
  на подобие MS Word.
Private MaxWidth As Single  ' для фиксации длины текстового поля
Private sngX As Single, sngY As Single ' для определения координаты

Const SP As String = " " ' разделитель слов

' Идея процедуры заключается в следующем: _
  текстовое поле должно быть скрытым (т.е. свойство Visible = False), оно _
  необходимо нам разве что для измерения текста, а сам текст будет _
  воссоздан с помощью метода "Print" объекта "Report".
Public Sub TextAlign(Rpt As Access.Report, TextboxName As String)
    Dim ArrWords As Variant ' для массива строк
    Dim strPrint As String, strTemp As String
    Dim i As Integer
    
    With Rpt.Controls.Item(TextboxName)
        If IsNull(.Value) = True Or Len(.Value) =  0  Then Exit Sub
        ' Распределяем текст поля на массив строк с помощью функции "Split" и при _
          этом не укажем параметр функции "limit". Из-за отсутствия параметра _
          "limit" получим ровно столько элементов массива, сколько пробелов в _
          тексте +  1 .
        ArrWords = Split(Replace(.Value, vbCrLf, SP & Chr( 13 ) & SP), SP)
        
        ' Максимальная длина строк не может быть больше ширины поля. Здесь следует _
          "запомнить" ширину поля, чтобы в условиях IF можно было сравнивать ширину _
          текста.
        MaxWidth = .Width
        
        ' Здесь зафиксируем координаты текстового поля.
        sngX = .Left
        sngY = .Top
        
        ' Чтобы точно измерить длину текста с помощью метода "TextWidth" _
          следует свойства шрифта текстового поля присвоить свойствам шрифта _
          самого отчёта.
        Rpt.FontName = .FontName
        Rpt.FontSize = .FontSize
        Rpt.FontBold = .FontBold
        Rpt.FontItalic = .FontItalic
    End With
    
    ' Теперь прокручиваем массив и обратно собираем слова
    For i =  0  To UBound(ArrWords)
        strPrint = strPrint & ArrWords(i) & SP
        
        If i < UBound(ArrWords) Then
            ' Если текст содержит перевод строки, т.е. Chr(13), _
              то следует разбить на  2  текста и распечатать отдельно. _
              Иначе отчёт будет выглядит непрезентабельно. Поэтому _
              проверяем имеется ли символ Chr( 13 )
            If ArrWords(i +  1 ) <> Chr( 13 ) Then
                ' Добавив очередное слово из массива проверяем длину текста
                strTemp = strPrint & ArrWords(i +  1 )
                If Rpt.TextWidth(strTemp) > MaxWidth Then
                    ' Полученный текст больше длины текстового поля. Поначалу _
                      убираем правый, крайный пробел.
                    strPrint = RTrim$(strPrint)
                    ' Теперь с помощью процедуры "PrintText" печатаем текст. _
                      Необходимо передать процедуре количество пробелов для _
                      параметра "SpacesQuantity", чтобы процедура могла чуть-чуть _
                      расширить пробелы, чтобы выровнить текст. Для этого идеально _
                      подходит "i". Если i =  0 , то это первое слово и _
                      соответственно пробела пока нет. А если i =  1 , то слов  2  и _
                      соответственно пробел  1  и т.д.
                    PrintText Rpt, strPrint, True
                    strPrint = ""
                    strTemp = ""
                End If
            Else
                strTemp = RTrim$(strTemp)
                PrintText Rpt, strTemp, False
                strPrint = ""
                strTemp = ""
                i = i +  1 
            End If
        Else
            ' Если процедура дошла до этой точки, то это означает, что _
              мы дошли до последнего элемента массива. Здесь также _
              убираем крайний правый символ.
            strPrint = RTrim$(strPrint)
            ' Запускаем процедуру "PrintText"
            If Len(strPrint) >  0  Then
                PrintText Rpt, strPrint, False
            End If
            strPrint = ""
            strTemp = ""
        End If
    Next i
End Sub
Private Sub PrintText(Rpt As Access.Report, strPrint As String, ExtendText As Boolean)
    ' Процедура не расширяет все символы текста, как это делает Access, а _
      расширяет пробелы, как это делает Microsoft Word. Так более красивее _
      выглядят отчёты.
    Dim ArrWords As Variant, AddlSpace As Single, x As Single, i As Byte
    
    If Len(strPrint) =  0  Then Exit Sub
    
    ArrWords = Split(strPrint, SP)
    ' А если количество пробелов указано, то следует найти недостающее _
      пространство (т.е. разница между текстом "strPrint" и длиной _
      текстового поля - maxWidth) и поделить на количество пробелов. _
      При распечатке между слов следует добавить полученное число, _
      чтобы ровномерно расширить пробелы.
    If UBound(ArrWords) >  0  And ExtendText = True Then
        AddlSpace = (MaxWidth - Rpt.TextWidth(strPrint)) / UBound(ArrWords)
    End If
    x = sngX
    ' Заново прокручиваем массив строк, но на этот раз чтобы распечатать.
    For i =  0  To UBound(ArrWords)
        ' Следует определиться с координатами текста
        Rpt.CurrentX = x
        Rpt.CurrentY = sngY
        Rpt.Print ArrWords(i)
        x = x + Rpt.TextWidth(ArrWords(i) & SP) + AddlSpace
    Next i
    
    ' Для следующей строки следует вертикаль сдвинуть вниз.
    sngY = sngY + Rpt.TextHeight(strPrint)
End Sub

Private Sub Details_Format(Cancel As Integer, FormatCount As Integer)
    TextAlign Me, "Text1"
    TextAlign Me, "Text2"
End Sub