Public Function ExecuteSQL(ByVal SQL As String, _
                            Optional ByRef aCon As ADODB.Connection = Nothing, _
                            Optional ByVal Params As Variant = Null) As Variant

'функция для выполниения запросов типа INSERT,UPDATE,DELEDE
'приемущество функции - экранируются символы в  значениях типа "д'Артаньян", "ООО ""Василек"""
'Params - передается массив параметров, важно чтобы было соответствие переданных и в запросе
'также важен порядок следования параметров
'можно запускать и динамические запросы и сохраненные
'executesql("insert into people (f_name) values(?)",con,"параметр1")
'executesql("exec add_person",con,Array("параметр1","параметр2","парамет3"))
'результат функуции - количетство обработанных строк
'в случае неудачи возвращает NULL
On Error GoTo Except
    If SQL = "" Then
        ExecuteSQL = Null
        Exit Function
    End If
    Dim RecAffected
    Dim cmd As New ADODB.Command
    If aCon Is Nothing Then
        cmd.ActiveConnection = CurrentProject.Connection
    Else
        cmd.ActiveConnection = aCon
    End If
    cmd.CommandType = adCmdText
    cmd.CommandText = SQL

    If IsNull(Params) Then
        cmd.Execute RecAffected
    Else
        cmd.Execute RecAffected, Params, adCmdText
    End If
    
    ExecuteSQL = RecAffected
    
Exit_Here:
    Set cmd = Nothing
    Exit Function

Except:
    ExecuteSQL = Null
    Select Case Err.Number

        Case Else
            MsgBox "Произошла ошибка " & Err.Number & vbNewLine & _
                Err.Description, vbInformation
        'Debug.Print Err.Number; Err.Description
    
    End Select
    Resume Exit_Here

End Function