'Code from "VBA Developer's Handbook" (Sybex, 1997): 

Private Const vbKeyScrollLock = &H91

Private Declare Function GetKeyState Lib "user32" (ByVal nVirtKey As Long) As Integer
Private Declare Function GetKeyboardState Lib "user32" (pbKeyState As Byte) As Long
Private Declare Function SetKeyboardState Lib "user32" (lppbKeyState As Byte) As Long
 
Public Function GetCapslock() As Boolean
     ' Return or set the Capslock toggle. 
    GetCapslock = CBool(GetKeyState(vbKeyCapital) And  1 )
End Function
 
Public Function GetNumlock() As Boolean
     ' Return or set the Numlock toggle. 
    GetNumlock = CBool(GetKeyState(vbKeyNumlock) And  1 )
End Function
 
Public Function GetScrollLock() As Boolean
     ' Return or set the ScrollLock toggle. 
    GetScrollLock = CBool(GetKeyState(vbKeyScrollLock) And  1 )
End Function
 
Public Sub SetCapslock(Value As Boolean)
     ' Return or set the Capslock toggle. 
    Call SetKeyState(vbKeyCapital, Value)
End Sub
 
Public Sub SetNumlock(Value As Boolean)
     ' Return or set the Numlock toggle. 
    Call SetKeyState(vbKeyNumlock, Value)
End Sub
 
Public Sub SetScrollLock(Value As Boolean)
     ' Return or set the ScrollLock toggle. 
    Call SetKeyState(vbKeyScrollLock, Value)
End Sub
 
Public Sub SetKeyState(intKey As Integer, fTurnOn As Boolean)
     ' Retrieve the keyboard state, set the particular 
     ' key in which you're interested, and then set 
     ' the entire keyboard state back the way it 
     ' was, with the one key altered. 
    Dim abytBuffer( 0  To  255 ) As Byte
    GetKeyboardState abytBuffer( 0 )
    abytBuffer(intKey) = CByte(Abs(fTurnOn))
    SetKeyboardState abytBuffer( 0 )
End Sub

Private Sub FieldName_GotFocus()
 SetCapslock True
End Sub

Private Sub FieldName_LostFocus()
 SetCapslock False
End Sub