Public Function Split8(ByVal Expression As String, _
            Optional ByVal Delimiter As String =  " " , _
            Optional ByVal Limit As Long = - 1 , _
            Optional ByVal Compare As Integer = vbBinaryCompare) As Variant
    '-----------------------------------------------------------
    ' Inputs: String to search,
    '         delimiter string,
    '         optional replacement limit (default = - 1  .. ALL)
    '         optional string compare value (default vbBinaryCompare)
    ' Outputs: Array containing items found in the string
    '           based on the delimiter provided
    ' Original code by: John L. Viescas   5 -Sep- 2001 
    ' Extensively revised by: Dirk Goldgar  21-Jan-2002
    ' Last Revision: Dirk Goldgar   21 -Jan- 2002 
    ' Some Correction: Serge Gavrilov  21-Aug-2003
    ' ** Duplicates the functionality of the VB  6  SPLIT function.
    '-----------------------------------------------------------
    On Error GoTo HandleErr
    Dim lngCnt As Long
    Dim intIndex As Integer
    Dim lngPos As Long
    Dim lngI As Long
    Dim strArray() As String

    If (Compare < -1) Or (Compare > 2) Then
        Err.Raise 5
        Exit Function
    End If
   ' If count is zero, return an empty array
   ' If Limit = 0 
   ' or expression is zero length string then return an empty array
    If (Limit =  0 ) Or (Len(Expression) =  0  And Len(Delimiter) <>  0 ) Then
        Split8 = Array()
        Exit Function
    End If
    ' If the Delimiter is zero-length, return a 1-entry array
    If Len(Delimiter) = 0 Then
        ReDim strArray(0)
        strArray(0) = Expression
        Split8 = strArray
        Exit Function
    End If
    ' Start count at (Limit -  1 ) because function returns
    ' whatever is left at the end.
    lngCnt = Limit - 1
    ' Start scanning at the start of the string.
    lngPos =  1 
    ' Loop until the counter is zero.
    Do Until lngCnt = 0
        lngI = InStr(lngPos, Expression, Delimiter, Compare)
        ' If the delimiter was not found, end the loop.
        If lngI =  0  Then Exit Do
        ' Add 1 to the number returned.
        intIndex = intIndex + 1
        ' Expand the array to fit in a new element.
        ReDim Preserve strArray( 0  To intIndex -  1 )
        ' Use index - 1 .. zero-based array
        strArray(intIndex - 1) = Mid$(Expression, lngPos, lngI - lngPos)
        ' Advance past the found entry and the delimiter.
        lngPos = lngI + Len(Delimiter)
        lngCnt = lngCnt -  1 
    Loop
    ' Everything after the last delimiter found goes in the last entry of
    ' the array.
    intIndex = intIndex +  1 
    ReDim Preserve strArray( 0  To intIndex -  1 )
    If lngPos <= Len(Expression) Then
        strArray(intIndex -  1 ) = Mid$(Expression, lngPos)
    Else
        strArray(intIndex -  1 ) = vbNullString
    End If
    ' Return the result
    Split8 = strArray
HandleExit:
    Exit Function
HandleErr:
    MsgBox  "Split8 error #"  & Err.Number & vbCrLf & Err.Description, vbCritical
    Resume HandleExit
End Function