1, на фиг нада
2, создание таблы
в тек. базе.
естли табе нада в другой
то вместо CurrentProject.Connection
исп. другой.

Public Sub CreateOrdersTable()
Dim cat As ADOX.Catalog
Dim tblOrders As ADOX.Table
Dim col1 As ADOX.Column
Dim col2 As ADOX.Column

Set cat = New ADOX.Catalog
cat.ActiveConnection = CurrentProject.Connection

' Delete the table, if it exists.
On Error Resume Next
cat.Tables.Delete "tblOrders1"
On Error GoTo 0

Set tblOrders = New ADOX.Table
tblOrders.Name = "tblOrders1"

Set col1 = New ADOX.Column
col1.Name = "OrderID"
col1.Type = adInteger
Set col2 = New ADOX.Column
col2.Name = "CustomerName"
col2.Type = adVarWChar
col2.DefinedSize = 30

With tblOrders.Columns
.Append col1
.Append col2
End With

With tblOrders.Columns("OrderID")
.ParentCatalog = cat
.Properties("AutoIncrement") = True
End With

With cat.Tables
.Append tblOrders
.Refresh
End With

Application.RefreshDatabaseWindow
Set col1 = Nothing
Set col2 = Nothing
Set cat = Nothing
Set tblOrders = Nothing
End Sub

Public Sub CreateOrdersTable2()
Dim cat As ADOX.Catalog
Dim tblOrders As ADOX.Table

Set tblOrders = New ADOX.Table
Set cat = New ADOX.Catalog
cat.ActiveConnection = CurrentProject.Connection

' Delete the table, if it exists.
On Error Resume Next
cat.Tables.Delete "tblOrders2"
On Error GoTo 0

' The table object is already created, so
' just assign its properties
tblOrders.Name = "tblOrders2"

' Create the columns by appending them
With tblOrders.Columns
.Append "OrderID", adInteger
.Append "CustomerName", adVarWChar, 30
End With

With tblOrders.Columns("OrderID")
.ParentCatalog = cat
.Properties("AutoIncrement") = True
End With

With cat.Tables
.Append tblOrders
.Refresh
End With

Application.RefreshDatabaseWindow
Set cat = Nothing
Set tblOrders = Nothing
End Sub