В данном примере сначала создается форма, имеющая базовую
таблицу «Заказы». Затем функция CreateControl создает поле
и присоединенную к нему подпись в форме.

Sub NewControls()
	Dim frm As Form
	Dim ctlLabel As Control, ctlText As Control
	Dim intDataX As Integer, intDataY As Integer
	Dim intLabelX As Integer, intLabelY As Integer

	' Создает новую форму с базовой таблицей «Заказы».
	Set frm = CreateForm
	frm.RecordSource = "Заказы"
	' Задает координаты элементов управления.
	intLabelX =  100 
	intLabelY =  100 
	intDataX =  1000 
	intDataY =  100 
	' Создает в области данных неприсоединенное поле стандартных размеров.

Set ctlText = CreateControl(frm.Name, acTextBox, , "", "", _
		intDataX, intDataY)
	' Создает надпись, присоединенную к полю.
	Set ctlLabel = CreateControl(frm.Name, acLabel, , ctlText.Name, _
		 "NewLabel" , intLabelX, intLabelY)
	' Восстанавливает окно формы.
	DoCmd.Restore
End Sub

В данном примере создается форма, содержащая кнопку,
и выводится сообщение, предлагающее пользователя удалить эту кнопку.
При нажатии кнопки Да в диалоговом окне из формы удаляется кнопка.

Sub DeleteCommandButton()
	Dim frm As Form, ctlNew As Control
	Dim strMsg As String, intResponse As Integer, intDialog As Integer

	' Создает новую форму и получает указатель на нее.
	Set frm = CreateForm
	' Создает новую кнопку.
	Set ctlNew = CreateControl(frm.Name, acCommandButton)
	' Восстанавливает окно формы.
	DoCmd.Restore
	' Задает текст подписи.
	ctlNew.Caption =  "Новая кнопка" 
	' Задает размер элемента управления.
	ctlNew.SizeToFit
	' Предлагает удалить кнопку.

strMsg =  "Удаляем кнопку "  & ctlNew.Name & ". Продолжить?" 
	' Задает кнопки, которые выводятся в диалоговом окне.
	intDialog = vbYesNo + vbCritical + vbDefaultButton2
	intResponse = MsgBox(strMsg, intDialog)
	If intResponse = vbYes Then
		' Удаляет элемент управления.
		DeleteControl frm.Name, ctlNew.Name
	End If
End Sub