Private mwks As DAO.Workspace
Private mfInTrans As Boolean

Private Const adhcSource _
 As String =  "qrySubformTransactions" 

Private Sub Form_Unload(Cancel As Integer)

    'Предположим, что юзер захотел сохранить изменения,
    ' а не отменить их. Вы можете спросить его об этом
    ' здесь, использовав переменную mfInTrans.
    
    If mfInTrans Then
        mwks.CommitTrans
    End If
    Set mwks = Nothing
End Sub

Private Sub ResetData()
    Dim db As DAO.Database
    Dim qdf As DAO.QueryDef
    Dim rst As DAO.Recordset
    Dim prm As DAO.Parameter
    Dim strSource As String
        
    ' Отмена в подформе.
    
    ' Обратите внимание на намеренный недостаток обработки ошибок.
    ' Этот только пример.
    
    If mfInTrans Then
        mwks.CommitTrans
    End If
    
    Set mwks = DBEngine.CreateWorkspace( "mwks" ,  "Admin" , "")
    Set db = mwks.OpenDatabase(CurrentDb.Name)
    Set qdf = db.QueryDefs(adhcSource)
    
    For Each prm In qdf.Parameters
        prm.Value = Eval(prm.Name)
    Next prm
    
    Me.Painting = False
    Set rst = qdf.OpenRecordset
    rst.LockEdits = False
    Set subOrders.Form.Recordset = rst
    Me.Painting = True
    
    ' Начинаем новую транзакцию
    mwks.BeginTrans
    mfInTrans = True
    cmdRollbackSubform.Enabled = False
End Sub

Private Sub Form_Dirty(Cancel As Integer)
    cmdRollbackSubform.Enabled = True
End Sub

Private Sub cmdRollbackSubform_Click()
    Me.Undo
    If mfInTrans Then
        mwks.Rollback
        mfInTrans = False
        
        'передадим фокус на люб.контрол, т.к. эта кнопка блокируется
        txtFirstName.SetFocus
        Call ResetData
    End If
End Sub

Private Sub Form_Current()
    Call ResetData
End Sub

Private Sub Form_BeforeUpdate(Cancel As Integer)
    If IsSubForm(Me) Then
        If IsNull(Me.CustomerId) Then
            Me.CustomerId = Me.Parent.CustomerId
        End If
    End If
End Sub

Private Sub Form_Dirty(Cancel As Integer)
    If IsSubForm(Me) Then
        Me.Parent.cmdRollbackSubform.Enabled = True
    End If
End Sub

Private Function IsSubForm(frm As Form) As Boolean
    'Верно ли что, эта форма в настоящее время загруженном как субформа?
    'Проверим это через свойство Parent.
    Dim strName As String
    On Error Resume Next
    strName = frm.Parent.Name
    IsSubForm = (Err.Number =  0 )
    Err.Clear
End Function