Вопрос глупый, но что поделать надо же учиться. В сети есть множество примеров кода на http://msaccess.da.ru/ к примеру. Ситуация: скопировал код, вставил в модуль. Вопрос: как грамотно им воспльзоваться? Т.е по шагам, как и что.
Пример кода хотя бы такой:
Sub Cycle01_1()
'© NSA Programmer, 2001. http://www.msaccess.ru ~ E-mail: nsa@chat.ru ~ ICQ: 7349882
'----------------------------------------------------------------------
' Цикл по записям таблицы "tblPeoples" от начала до конца
'----------------------------------------------------------------------
Dim db As Database 'База данных
Dim rs As Recordset 'Набор записей
Dim str As String 'Строка
Dim lngRecordCount As Long 'Количество записей в наборе записей
Set db = CurrentDb ' db - текушая база данных
Set rs = db.OpenRecordset("tblPeoples", dbOpenDynaset) ' rs - набор записей на основе таблицы "tblPeoples"
'При инициализации набора записей мы можем точно определить, есть ли в этом наборе записи или нет.
'Свойство "RecordCount" набора записей посли его инициализации, по идее, должна сождержать количество
'записей набора, однако это не так. Если в наборе есть записи это свойство отлично от нуля, но не содержит
'их количество. Для определения количества записей необходимо перейти на последнюю запись набора, и после
'этого в свойстве "RecordCount" будет находиться количество записей набора.
If rs.RecordCount <> 0 Then 'Если в наборе rs есть записи...

rs.MoveLast 'Переходим на последнюю запись (чтобы "RecordCount" содержало верное значение)
lngRecordCount = rs.RecordCount 'Считываем количество записей в переменную
rs.MoveFirst 'Переходим на первую запись набора

'Заполняем текстовую переменную str количеством записей
str = "Количество записей в таблице ""tblPeoples"": " & lngRecordCount & vbCrLf

'Свойство EOF (End Of File) набора записей становиться истинным ПОСЛЕ последней записи набора,
'точно как и свойство BOF (Begin Of File) становиться истинным ПЕРЕД первой записью набора.
'Набор записей можно изобразить примерно так:
'
' BOF
' First Record
' ............
' ............
' ............
' Last Record
' EOF
'
'Цикл "Пока не кончатся записи в наборе rs"
Do Until rs.EOF
'Добавляем в переменную str имнена полей, их значения и символ перевода строки
str = str & "ID_People: " & rs![ID_People] & vbCrLf
str = str & "ID_RecordStatus: " & rs![ID_RecordStatus] & vbCrLf
str = str & "LastName: " & rs![LastName] & vbCrLf
str = str & "FirstName: " & rs![FirstName] & vbCrLf
str = str & "MiddleName: " & rs![MiddleName] & vbCrLf
str = str & "PeopleSex: " & rs![PeopleSex] & vbCrLf
str = str & "BirthDate: " & rs![BirthDate] & vbCrLf
str = str & "------------" & vbCrLf
rs.MoveNext 'Переходим на следующую запись
Loop 'Конец цикла
Else 'Если записей нет...
'Заполняем текстовую переменную str сообщением об отсутствии записей
str = "Таблица ""tblPeoples"" не содержит записей."
End If
'Печатаем содержимое переменной str в окне отладки
Debug.Print str
rs.Close 'Закрываем переменную набора записей
db.Close 'Закрываем переменную базы данных
End Sub