Function AccessToExcelAutomation()
   
   Dim rstProjects As New ADODB.Recordset
   Dim intCurrTask As Integer
   Dim wbkNew As Excel.Workbook, wksNew As Excel.Worksheet
   Dim rngCurr As Excel.Range
   
   On Error GoTo Error_OLEAccessToExcel
   
   '-- Open the current database and projects table
   rstProjects.Open _
            "Select Tasks, Resources, CInt(Duration) from tblProjects", _
            CurrentProject.Connection, adOpenKeyset
   
   Set appExcel = New Excel.Application
   Set wbkNew = appExcel.Workbooks.Add
   Set wksNew = wbkNew.Worksheets.Add
   appExcel.Visible = True
    
   With wksNew
      ' -- Create the Column Headings
 
      .Cells( 1 ,  1 ).Value =  "Task" 
      .Cells( 1 ,  2 ).Value =  "Resource" 
      .Cells( 1 ,  3 ).Value =  "Hours" 
   End With
   
   rstProjects.MoveLast
   rstProjects.MoveFirst
   
   Set rngCurr = wksNew.Range(wksNew.Cells( 2 ,  1 ), _
             wksNew.Cells( 2  + rstProjects.RecordCount,  3 ))
   
   rngCurr.CopyFromRecordset rstProjects
  
   ' -- Create the calculation that sums up the Duration Column
 
   wksNew.Cells( 2  + rstProjects.RecordCount,  3 ).Value = _
             "=SUM(C2:C"  & LTrim(Str(rstProjects.RecordCount) +  1 ) &  ")" 
   
   wksNew.Columns( "A:C" ).AutoFit
   
   rstProjects.Close
   Set rstProjects = Nothing
   
   Exit Function
   
Error_OLEAccessToExcel:
   
   Beep
   MsgBox  "The Following OLE Error has occurred:"  & vbCrLf & Err.Description, vbCritical,  "OLE Error!" 
   Set appExcel = Nothing
   Exit Function
      
End Function