Private WithEvents mlblLabel As Label
Private mfrmForm As Form
Private mlngOldX As Long, mlngOldY As Long
Private mlngOldXForDblClick As Long, mlngOldYForDblClick As Long
Private mstrFunctionOnClick As String, mstrFunctionOnDblClick As String
Private mstrFunctionOnMouseDown As String, mstrFunctionOnMouseMove As String, mstrFunctionOnMouseUp As String

Public TopBorder As Long, BottomBorder As Long, LeftBorder As Long, RightBorder As Long
Public HorizontalMove As Boolean, HorizontalSizing As Boolean, HorizontalSizePointer As Boolean
Public VerticalMove As Boolean, VerticalSizing As Boolean, VerticalSizePointer As Boolean
Public ShiftKey As Boolean, AltKey As Boolean, CtrlKey As Boolean
Public LeftButton As Boolean, RightButton As Boolean
Public CoordinateX As Long, CoordinateY As Long

Private mbytBorder As Byte

Public Property Get Label() As Label
Set Label = mlblLabel
End Property
Public Property Set Label(lblNewLabel As Label)
Set mlblLabel = lblNewLabel
Set mfrmForm = mlblLabel.Parent
RightBorder = mfrmForm.Width
BottomBorder = mfrmForm.Section( 0 ).Height
End Property

Private Sub mlblLabel_Click()
If Len(mstrFunctionOnClick) >  0  Then Application.Run mstrFunctionOnClick, Me
End Sub

Private Sub mlblLabel_DblClick(Cancel As Integer)
mlngOldX = mlngOldXForDblClick
mlngOldY = mlngOldYForDblClick
If Len(mstrFunctionOnDblClick) >  0  Then Application.Run mstrFunctionOnDblClick, Me
End Sub

Private Sub mlblLabel_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)
mlngOldX = X
mlngOldY = Y
mlngOldXForDblClick = X
mlngOldYForDblClick = Y

If Len(mstrFunctionOnMouseDown) >  0  Then
    Call SetKeysButtonsCoordinates(Button, Shift, X, Y)
    Application.Run mstrFunctionOnMouseDown, Me
    Call SetKeysButtonsCoordinates
End If
End Sub

Private Sub mlblLabel_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
Dim lngNewX As Long, lngNewY As Long

If Len(mstrFunctionOnMouseMove) >  0  Then
    Call SetKeysButtonsCoordinates(Button, Shift, X, Y)
    Application.Run mstrFunctionOnMouseMove, Me
    Call SetKeysButtonsCoordinates
End If

If Screen.MousePointer =  0  Then
    If HorizontalMove Then
        lngNewX = mlblLabel.Left + X - mlngOldX
        If lngNewX >= Me.LeftBorder And lngNewX <= Me.RightBorder - mlblLabel.Width Then
           mlblLabel.Left = lngNewX
        ElseIf lngNewX < Me.LeftBorder Then
           mlblLabel.Left = Me.LeftBorder
        ElseIf lngNewX > Me.RightBorder - mlblLabel.Width Then
           mlblLabel.Left = Me.RightBorder - mlblLabel.Width
        End If
    End If
    
    If VerticalMove Then
        lngNewY = mlblLabel.Top + Y - mlngOldY
        If lngNewY >= Me.TopBorder And lngNewY <= Me.BottomBorder - mlblLabel.Height Then
           mlblLabel.Top = lngNewY
        ElseIf lngNewY < Me.TopBorder Then
           mlblLabel.Top = Me.TopBorder
        ElseIf lngNewY > Me.BottomBorder - mlblLabel.Height Then
           mlblLabel.Top = Me.BottomBorder - mlblLabel.Height
        End If
    End If
End If

If Not (HorizontalSizing Or VerticalSizing) Then
    If  0  < X And X <  45  Then
        mbytBorder =  1 
    ElseIf mlblLabel.Width -  45  < X And X < mlblLabel.Width Then
        mbytBorder =  3 
    ElseIf  0  < Y And Y <  45  Then
        mbytBorder =  2 
    ElseIf mlblLabel.Height -  45  < Y And Y < mlblLabel.Height Then
        mbytBorder =  4 
    Else
        mbytBorder =  0 
    End If
    
    If mbytBorder =  1  Or mbytBorder =  3  And HorizontalSizePointer Then
        Screen.MousePointer =  9 
    ElseIf mbytBorder =  2  Or mbytBorder =  4  And VerticalSizePointer Then
        Screen.MousePointer =  7 
    Else
        Screen.MousePointer =  0 
    End If
End If

If HorizontalSizing And Screen.MousePointer =  9  Then
    If mbytBorder =  1  Then
        If mlblLabel.Width - X >=  60  Then
            If mlblLabel.Left + X >= Me.LeftBorder Then
                mlblLabel.Width = mlblLabel.Width - X
                mlblLabel.Left = mlblLabel.Left + X
            End If
        Else
            mlblLabel.Width =  60 
        End If
    Else
        If X >  60  Then
            If mlblLabel.Left + X <= Me.RightBorder Then mlblLabel.Width = X
        Else
            mlblLabel.Width =  60 
        End If
    End If
End If

If VerticalSizing And Screen.MousePointer =  7  Then
    If mbytBorder =  2  Then
        If mlblLabel.Height - Y >=  60  Then
            If mlblLabel.Top + Y >= Me.TopBorder Then
                mlblLabel.Height = mlblLabel.Height - Y
                mlblLabel.Top = mlblLabel.Top + Y
            End If
        Else
            mlblLabel.Height =  60 
        End If
    Else
        If Y +  15  >  60  Then
            If mlblLabel.Top + Y <= Me.BottomBorder Then mlblLabel.Height = Y
        Else
            mlblLabel.Height =  60 
        End If
    End If
End If
End Sub


Private Sub mlblLabel_MouseUp(Button As Integer, Shift As Integer, X As Single, Y As Single)
mlngOldX =  0 
mlngOldY =  0 

If Len(mstrFunctionOnMouseUp) >  0  Then
    Call SetKeysButtonsCoordinates(Button, Shift, X, Y)
    Application.Run mstrFunctionOnMouseUp, Me
    Call SetKeysButtonsCoordinates
End If
End Sub

Public Property Get OnClick() As String
OnClick = mstrFunctionOnClick
End Property
Public Property Let OnClick(ByVal strNewValue As String)
mstrFunctionOnClick = strNewValue
If Len(mstrFunctionOnClick) >  0  Then mlblLabel.OnClick =  "[Event Procedure]" 
End Property

Public Property Get OnDblClick() As String
OnDblClick = mstrFunctionOnDblClick
End Property
Public Property Let OnDblClick(ByVal strNewValue As String)
mstrFunctionOnDblClick = strNewValue
If Len(mstrFunctionOnDblClick) >  0  Then mlblLabel.OnDblClick =  "[Event Procedure]" 
End Property

Public Property Get OnMouseUp() As String
OnMouseUp = mstrFunctionOnMouseUp
End Property
Public Property Let OnMouseUp(ByVal strNewValue As String)
mstrFunctionOnMouseUp = strNewValue
If Len(mstrFunctionOnMouseUp) >  0  Then mlblLabel.OnMouseUp =  "[Event Procedure]" 
End Property

Public Property Get OnMouseMove() As String
OnMouseMove = mstrFunctionOnMouseMove
End Property
Public Property Let OnMouseMove(ByVal strNewValue As String)
mstrFunctionOnMouseMove = strNewValue
If Len(mstrFunctionOnMouseMove) >  0  Then
    mlblLabel.OnMouseMove =  "[Event Procedure]" 
    mlblLabel.OnMouseUp =  "[Event Procedure]" 
    mlblLabel.OnMouseDown =  "[Event Procedure]" 
End If
End Property

Public Property Get OnMouseDown() As String
OnMouseDown = mstrFunctionOnMouseDown
End Property
Public Property Let OnMouseDown(ByVal strNewValue As String)
mstrFunctionOnMouseDown = strNewValue
If Len(mstrFunctionOnMouseDown) >  0  Then mlblLabel.OnMouseDown =  "[Event Procedure]" 
End Property

Private Sub SetKeysButtonsCoordinates(Optional intButton As Integer =  0 , Optional intKey As Integer =  0 , Optional sinCoordinateX As Single =  0 , Optional sinCoordinateY As Single =  0 )
Me.LeftButton = (intButton And acLeftButton) >  0 
Me.RightButton = (intButton And acRightButton) >  0 
Me.ShiftKey = (intKey And acShiftMask) >  0 
Me.CtrlKey = (intKey And acCtrlMask) >  0 
Me.AltKey = (intKey And acAltMask) >  0 
Me.CoordinateX = CLng(sinCoordinateX)
Me.CoordinateY = CLng(sinCoordinateY)
End Sub

Private mcolActionLabels As Collection

Private Sub Form_Open(Cancel As Integer)
Dim albActionLabel As clsActionLabel
Dim i As Integer
 
Set mcolActionLabels = New Collection

For i =  1  To  2 
    Set albActionLabel = New clsActionLabel
    Set albActionLabel.Label = Me( "lblTest"  & Trim(Str(i)))
    albActionLabel.OnMouseMove =  "OnLabelMouseMove" 

'    albActionLabel.OnClick = "OnLabelClick"
'    albActionLabel.OnDblClick =  "OnLabelDblClick" 
'    albActionLabel.OnMouseDown = "OnLabelMouseDown"
'    albActionLabel.OnMouseUp =  "OnLabelMouseUp" 
    
    mcolActionLabels.Add albActionLabel, albActionLabel.Label.Name
Next
End Sub

Public Function OnLabelMouseMove(albActionLabel As clsActionLabel)
albActionLabel.HorizontalMove = albActionLabel.LeftButton
albActionLabel.HorizontalSizePointer = True
albActionLabel.HorizontalSizing = albActionLabel.LeftButton

albActionLabel.VerticalMove = albActionLabel.LeftButton 
albActionLabel.VerticalSizePointer = True
albActionLabel.VerticalSizing = albActionLabel.LeftButton
End Function

albActionLabel.HorizontalMove = albActionLabel.RightButton
albActionLabel.HorizontalSizePointer = albActionLabel.CtrlKey
albActionLabel.HorizontalSizing = albActionLabel.LeftButton and albActionLabel.CtrlKey

Public Function OnLabelMouseUp(albActionLabel As clsActionLabel)
MsgBox  "Label Name = "  & albActionLabel.Label.Name
MsgBox  "Label Top = "  & albActionLabel.Label.Top 
MsgBox  "Label Left = "  & albActionLabel.Label.Left 
End Function