Sub ClientServerX2()
    Dim dbsCurrent As Database
    Dim qdfBestSellers As QueryDef
    Dim qdfBonusEarners As QueryDef
    Dim rstTopSeller As Recordset
    Dim rstBonusRecipients As Recordset
    Dim strAuthorList As String

    ' Open a database from which QueryDef objects can be created.'
    Set dbsCurrent = OpenDatabase( "DB1.mdb" )

    ' Create a temporary QueryDef object to retrieve'
    ' data from a Microsoft SQL Server database.'
    Set qdfBestSellers = dbsCurrent.CreateQueryDef( "")
    With qdfBestSellers
        .Connect = " ODBC;DATABASE=pubs;UID=sa;PWD=;DSN=Publishers "
        .SQL = " SELECT title, title_id FROM titles ORDER BY ytd_sales DESC "
        Set rstTopSeller = .OpenRecordset()
        rstTopSeller.MoveFirst
    End With

    ' Create a temporary QueryDef to retrieve data from'
    ' a Microsoft SQL Server database based on the results from the first query.'
    Set qdfBonusEarners = dbsCurrent.CreateQueryDef("  ")
    With qdfBonusEarners
        .Connect = " ODBC;DATABASE=pubs;UID=sa;PWD=;DSN=Publishers "
        .SQL = " SELECT * FROM titleauthor WHERE title_id = '" & _
            rstTopSeller!title_id & "' "
        Set rstBonusRecipients = .OpenRecordset()
    End With

    ' Build the output string.'
    With rstBonusRecipients
        Do While Not .EOF
            strAuthorList = strAuthorList & "    " & _
                !au_id & " :  $ " & (10  * !royaltyper) & vbCr
            .MoveNext
        Loop
    End With

    ' Display results.'
    MsgBox "Please send a check to the following  " & _
        " authors in the amounts shown: " & vbCr & _
        strAuthorList & " for outstanding sales of  " & _
        rstTopSeller!Title & " ."

    rstTopSeller.Close
    dbsCurrent.Close

End Sub