Для SysOp
Чем плох ваш вариант. Как правило, необходимость использовать асинхронный источник данных у формы возникает как следствие желания иметь возможность работать в приложении пока данные выбираются с сервера. То, что предложили вы работает следующим образом. Да, пока не приехала с сервера первая строчка данных асинхронного рекордсета работать в приложении можно. Но как только приезжает первая строчка и тут же рекордсет подсовывается форме, то в этот момент все дальнейшие действия в приложении будут блокированы до конца выборки данных асинхронным рекордсетом. Т.е. конечная цель не достигнута - в приложении по прежнему нельзя работать. Чтобы убедится в этом создайте такой источник данных, чтобы время от момента запроса к серверу до момента начала возврата на клиента первой строки набора исчислялось несколькими секундами, а время от момента начала возврата на клиента первой записи до момента окончания выборки исчислялось десятками секунд, именно так станет все очевидно.
Решение, позволяющее не блокировать действия в приложении я приводил тут:
http://am.rusimport.ru/MsAccess/Samples%5Cfrm000.htm

Повторю его здесь:

Option Compare Database
Option Explicit

Dim WithEvents rst As ADODB.Recordset
Dim blnФлаг As Boolean

Private Sub Form_Open(Cancel As Integer)
Set rst = New ADODB.Recordset
rst.Open "SELECT * FROM Таблица", CurrentProject.Connection, adOpenStatic, _
adLockOptimistic, adAsyncExecute
End Sub



Private Sub rst_MoveComplete(ByVal adReason As ADODB.EventReasonEnum, _
ByVal pError As ADODB.Error, _
adStatus As ADODB.EventStatusEnum, _
ByVal pRecordset As ADODB.Recordset)
If blnФлаг = False And rst.state = adStateOpen Then
blnФлаг = True
Set Me.Форма2.Form.Recordset = rst
End If
End Sub

Да, в этом случае данные появятся в подчиненной форме только после того, как приедут все записи(собственно как и у вас, несмотря на более раннее подсовывание), но все это время действия пользователя не будут блокироватся Access, как в вашем варианте.

>Дело в том, что ADODB.Connection не позволяет одновременно выполнять более одной команды
Честно говоря, я не понял, что вы этим хотели сказать. Если вы хотели сказать, что пока не будет выполнена первая, как вы говорите команда, а вторая будет ждать своей очереди, то вот опять же на основе предыдущего примера убедимся, что это не так:

Option Compare Database
Option Explicit
Dim con As ADODB.Connection
Dim WithEvents rstДолгий As ADODB.Recordset
Dim WithEvents rstКороткий As ADODB.Recordset
Dim blnФлагДолгий As Boolean
Dim blnФлагКороткий As Boolean

Private Sub Form_Open(Cancel As Integer)
Set con = New ADODB.Connection
con.ConnectionString = CurrentProject.Connection
con.Open
Set rstДолгий = New ADODB.Recordset
Set rstКороткий = New ADODB.Recordset
'Открываем рекордсет, у которого время выборки первой записи примерно секунд 10, а последней секунд 30
rstДолгий.Open "SELECT Выписка.* FROM Выписка WHERE (schet_dat > CONVERT(DATETIME, '2002-01-02 00:00:00', 102))", con, adOpenStatic, _
adLockOptimistic, adAsyncExecute
'Открываем рекордсет, у которого общее время выборки практически равно 0
rstКороткий.Open "SELECT * FROM test", con, adOpenStatic, _
adLockOptimistic, adAsyncExecute
End Sub


Private Sub rstДолгий_MoveComplete(ByVal adReason As ADODB.EventReasonEnum, _
ByVal pError As ADODB.Error, _
adStatus As ADODB.EventStatusEnum, _
ByVal pRecordset As ADODB.Recordset)
If blnФлагДолгий = False And rstДолгий.State = adStateOpen Then
blnФлагДолгий = True
Set Me.Recordset = rstДолгий
End If
End Sub

Private Sub rstКороткий_MoveComplete(ByVal adReason As ADODB.EventReasonEnum, _
ByVal pError As ADODB.Error, _
adStatus As ADODB.EventStatusEnum, _
ByVal pRecordset As ADODB.Recordset)
If blnФлагКороткий = False And rstКороткий.State = adStateOpen Then
blnФлагКороткий = True
Set Me.Recordset = rstКороткий
End If
End Sub
____________________________

В одном и том же конекшн con открываются два рекордесета. Первый(по очереди)- rstДолгий, второй rstКороткий. И не смотря на такую очередность при открытии, очередность возвращения данных с сервера будет обратной.

>Никак блокировок действий пользователя не произойдет, если для выполнения асинхронной
>операции открыть новое соединение
Если вы говорите о том же, что и я - о невозможности работать через интерфейс Access(признаки: характерный шум винчестера и отсутствие отклика на действия пользователя), то могу только повторить, что именно в вашем варианте в промежуток между возвратом на клиента первой записи набора и до полного окончания выборки будет иметь место блокировка действий пользователя со стороны Access, признаки которой я укал выше.

>Кроме того на событие Fetch_Progress можно посадить DoEvents, что сделает фетчинг еще
>более прозрачным для пользователя
Если в вашем варианте на событие Fetch_Progress посадить DoEvents, то это ничего не изменит, я проверял.

>с точки зрения модели событий ADO мое выглядит более логичным
Мне бы тоже хотелось, чтоб пользователь мог приступать к работе с формой как только на клиента приедет первая строка, но практика показала, я опять это повторю, что для того, чтоб не имела место, описанная мной выше блокировка со стороны Access, нужно подсовывать рекордсет форме на событии MoveComplete

Ну, сначала по поводу вашего уточнения:

>cn.Execute "sp_who", , adAsyncExecute
>cn.Execute "sp_lock", , adAsyncExecute

а зачем вы так делаете? Это практические тоже самое, что и:
rst.Open
'и сразу после этого опять
rst.Open

>Дело в том, что ADODB.Connection не позволяет одновременно выполнять более одной команды
ADODB.Connection все позволяет, надо было просто сделать примерно так:

Dim con As ADODB.Connection
Dim cmd1 As New ADODB.Command
Dim cmd2 As New ADODB.Command
Set con = CurrentProject.Connection
With cmd1
.CommandText = "СохраненнаяПроцедура1"
.CommandType = adCmdStoredProc
Set .ActiveConnection = con
.Execute , , adAsyncExecute
End With
With cmd2
.CommandText = "СохраненнаяПроцедура2"
.CommandType = adCmdStoredProc
Set .ActiveConnection = con
.Execute , , adAsyncExecute
End With

Заметьте, все в одном конекшн.

По поводу асинхронного рекордсета. Действительно, константа adAsyncFetchNonBlocking, которую вы сейчас нашли, решает проблему блокировки! В споре рождается истина
Кстати, достаточно и одной из констант - adAsyncFetchNonBlocking(можно и без суммы).
Ну и чтоб все это быстрее работало, лучше составить такой текст процедуры rs_FetchProgress:

Private Sub rs_FetchProgress(ByVal Progress As Long, ByVal MaxProgress As Long, adStatus As ADODB.EventStatusEnum, ByVal pRecordset As ADODB.Recordset)
Set Me.Recordset = rs
adStatus = adStatusUnwantedEvent
End Sub

Тогда событие будет выполнено только один раз