Call formsOpenLocate( "Anketa" ,  "[IDAnk] = "  & IDAnk)

Sub formsOpenLocate(vFormName, vCondition As Variant)
' Подпрограмма определяет форму, предварительно
' поставив курсор на первое поле последовательности
' заданной в условии
    Dim frm As Form
    Dim rst As ADODB.Recordset
    Dim lngCount As Long
    ' Открытие формы
    If Not formIsLoaded(vFormName) Then
        DoCmd.OpenForm vFormName, , , , , acHidden
    Else
        DoCmd.SelectObject acForm, vFormName
    End If
    ' Поиск первой последовательности
    Set frm = Forms(vFormName)
    If Not IsNull(vCondition) Then
        If Right(Trim(vCondition), 1) = "=" Then
            DoCmd.GoToRecord acForm, frm.Name, acNewRec
        Else
            DoCmd.GoToRecord acForm, frm.Name, acLast
            Set rst = frm.RecordsetClone
            rst.MoveFirst
            rst.Find vCondition
            If rst.EOF Then
                DoCmd.GoToRecord acForm, frm.Name, acNewRec
            Else
                frm.Bookmark = rst.Bookmark
            End If
        End If
    End If
    frm.Visible = True
End Sub

Function formIsLoaded(vFormName) As Integer
' Функция определяет, открыта ли форма с заданным именем
    Dim frm As Form
    formIsLoaded = False
    For Each frm In Forms
        If frm.Name = vFormName Then
            formIsLoaded = True
            Exit For
        End If
    Next frm
End Function