Именно для такого случая существует свойство формы InputParameters (на закладке Данные). Запиши туда @par Int = ФормаСполем!Поле.

Виноват. @par Int = Forms!ФормаСполем!Поле.

А куда ты будешь выводить результат процедуры?

Dim cmd As ADODB.Command, rst As ADODB.Recordset
Set cmd = New ADODB.Command
cmd.ActiveConnection = CurrentProject.Connection
cmd.CommandText = "dbo.Specification_report"
cmd.CommandType = adCmdStoredProc
cmd.Parameters.Append cmd.CreateParameter("@Specification_id", adInteger, adParamInput, , 972)
cmd.Prepared = False
Set rst = cmd.Execute

972 - это я просто жестко вбил значение параметра, а в твоем случае
cmd.Parameters.Append cmd.CreateParameter("@Specification_id", adInteger, adParamInput, , Forms!ТвояФорма!ТвоеПоле!)

Или вот еще тестовый примерчик, тут рекордсет открывается немного по другому, с возможностью явного задания типа курсора и типа блокировки:

Dim cn As ADODB.Connection
Dim cmd As ADODB.Command
Dim rs As ADODB.Recordset
Dim t As Double
Dim i As Long

t = Timer

Set cn = New ADODB.Connection

cn.ConnectionString = "PROVIDER=SQLOLEDB.1;INTEGRATED SECURITY=SSPI;" & _
"PERSIST SECURITY INFO=FALSE;INITIAL CATALOG=Store;DATA SOURCE=NEWSERVER"

cn.Open

Set cmd = New ADODB.Command
cmd.ActiveConnection = cn
cmd.CommandText = "dbo.sp_testSelect"
cmd.CommandType = adCmdStoredProc
cmd.Parameters.Append cmd.CreateParameter("@id", adInteger, adParamInput)
cmd.Prepared = True

Set rs = New ADODB.Recordset
rs.CursorLocation = adUseClient

For i = 1 To 1000
cmd.Parameters(0) = i
'Debug.Print rs.State & "," & rs.Status
rs.Open cmd, , adOpenStatic, adLockReadOnly
If rs.RecordCount > 0 Then rs.MoveLast
rs.Close
Next

Set rs = Nothing
Set cmd = Nothing

cn.Close
Set cn = Nothing