Public Type struct_cnn
    strSERVER As String
    strDATABASE As String
    strAPPLICATION As String
    cstrWinAuth As String
End Type

'массив строк (имена процедур), которые надо запустить после логина
Public ExecStrings As New Collection

Public m_cnn As struct_cnn

Public Function ReadConfig() As Boolean
Const cstrSERVER As String = "SERVER="
Const cstrDATABASE As String = "DATABASE="
Const cstrEXECUTE As String = "EXECUTE="
Const cstrWinAuth As String = "WinAuth="

Dim strConfigFileName As String
Dim s As String

m_cnn.strAPPLICATION = CurrentProject.Name
Dim p As Long
p = InStr( 1 , m_cnn.strAPPLICATION, ".")
If p >  0  Then
    m_cnn.strAPPLICATION = Left(m_cnn.strAPPLICATION, p -  1 )
End If

strConfigFileName = CurrentProject.Path & "\" & m_cnn.strAPPLICATION & ".cfg"
If Len(Dir(strConfigFileName)) =  0  Then
    MsgBox "Не найден конфигурационный файл приложения: " & strConfigFileName, vbExclamation, "Ошибка"
    ReadConfig = False
    Exit Function
End If

Dim i As Integer
For i =  1  To ExecStrings.Count
    ExecStrings.Remove  1 
Next i

Dim f As Integer
f = FreeFile
Open strConfigFileName For Input Access Read As #f
Do While Not EOF(f)
    Line Input #f, s
    
    If InStr( 1 , s, cstrSERVER) >  0  Then
        m_cnn.strSERVER = Mid(s, Len(cstrSERVER) +  1 , Len(s))
    End If
    
    If InStr( 1 , s, cstrDATABASE) >  0  Then
        m_cnn.strDATABASE = Mid(s, Len(cstrDATABASE) +  1 , Len(s))
    End If
    
    If InStr( 1 , s, cstrWinAuth) >  0  Then
        m_cnn.cstrWinAuth = Mid(s, Len(cstrWinAuth) +  1 , Len(s))
    End If
    
    If InStr( 1 , s, cstrEXECUTE) >  0  Then
            ExecStrings.Add Mid(s, Len(cstrEXECUTE) +  1 , Len(s))
    End If
    
Loop
Close #f

ReadConfig = True


End Function