Option Compare Database
Option Explicit

Private Declare Function GetForegroundWindow Lib "user32" () As Long
Private Declare Function GetWindowThreadProcessId Lib "user32" ( _
   ByVal hWnd As Long, lpdwProcessId As Any) As Long

Private Declare Function GetModuleHandle Lib "kernel32" _
   Alias "GetModuleHandleA" (ByVal lpModuleName As String) As Long

Private Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" ( _
   pDest As Any, pSource As Any, ByVal cb As Long)

Private Const WH_KEYBOARD_LL =  13 &     'enables monitoring of keyboard
                                       'input events about to be posted
                                       'in a thread input queue

Private Const HC_ACTION =  0 &           'wParam and lParam parameters
                                       'contain information about a
                                       'keyboard message

Private Type KBDLLHOOKSTRUCT
   vkCode As Long        'a virtual-key code in the range 1 to 254
   scanCode As Long      'hardware scan code for the key
   flags As Long         'specifies the extended-key flag,
                         'event-injected flag, context code,
                         'and transition-state flag
   time As Long          'time stamp for this message
   dwExtraInfo As Long   'extra info associated with the message
End Type

Private Const LLKHF_ALTDOWN = &H20&    'test the context code

Private Declare Function SetWindowsHookEx Lib "user32" _
   Alias "SetWindowsHookExA" ( _
   ByVal idHook As Long, ByVal lpfn As Long, ByVal hmod As Long, _
   ByVal dwThreadId As Long) As Long
Private Declare Function UnhookWindowsHookEx Lib "user32" ( _
   ByVal hHook As Long) As Long
Private Declare Function CallNextHookEx Lib "user32" ( _
   ByVal hHook As Long, ByVal nCode As Long, ByVal wParam As Long, _
   ByVal lParam As Long) As Long

Private m_hLLKbdHook As Long
                              
Private m_AccAppProcessId As Long

Public Sub blockKeys()
    If m_hLLKbdHook Then
        Exit Sub
    End If
    GetWindowThreadProcessId Application.hWndAccessApp, m_AccAppProcessId
    m_hLLKbdHook = SetWindowsHookEx(WH_KEYBOARD_LL, _
                                    AddressOf LowLevelKeyboardProc, _
                                    GetModuleHandle(vbNullString), _
                                     0 &)
    If m_hLLKbdHook Then
    Else
       MsgBox "Failed to install low-level keyboard hook - " & err.LastDllError
    End If
End Sub


Public Sub unblockKeys()
 If m_hLLKbdHook Then
    UnhookWindowsHookEx m_hLLKbdHook
    m_hLLKbdHook =  0 
 End If
End Sub

Public Function LowLevelKeyboardProc(ByVal nCode As Long, _
                                     ByVal wParam As Long, _
                                     ByVal lParam As Long) As Long
Dim kbdllhs As KBDLLHOOKSTRUCT
Dim ForeProcessId As Long
    If nCode = HC_ACTION Then
        CopyMemory kbdllhs, ByVal lParam, Len(kbdllhs)
        GetWindowThreadProcessId GetForegroundWindow, ForeProcessId
        If m_AccAppProcessId = ForeProcessId Then
            If kbdllhs.vkCode <=  40  And kbdllhs.vkCode >=  33  Then
                LowLevelKeyboardProc = CallNextHookEx(m_hLLKbdHook, nCode, wParam, lParam)
            Else
                LowLevelKeyboardProc =  1 
            End If
            Exit Function
        End If
    End If
End Function