'   В качестве управляющего списка могут выступать комбобокс или листбокс
'   Поэтому для корректного перехвата событий необходимо иметь
'   один из двух контролов
Private m_sControlType As String
Private WithEvents m_cmb As ComboBox
Private WithEvents m_lst As ListBox
Private m_ctl As Control ' это либо один лиьо второй

'   Генерация события для перехвата "наверху" для обработки выбранного значения в списке
Public Event ApplyWhere(vListValue As Variant, vCondition As Variant, iListIndex As Long, iListCount As Long, vListData() As Variant)

'
'   Для передачи методов в родной класс
'
Public Property Let ListValue(VALUE As Variant)
    m_ctl.VALUE = VALUE
    DoEvents
    m_ctl.Requery
    DoEvents
    m_vListValue = m_ctl.VALUE
End Property

Public Property Get ListIndex() As Long
    m_iListIndex = m_ctl.ListIndex
    ListIndex = m_ctl.ListIndex
End Property

Public Property Get ListCount() As Long
    m_iListCount = m_ctl.ListCount
    ListCount = m_ctl.ListCount
End Property

'
'   Инициализация и запись фактического аксесовского контрола
'
Public Function Constructor _
( _
    SysData As SysData, _
    ctl As Control, sListKey As String, sListCode As String, _
    sRoleName As String, _
    Optional sServerOrClientMode As String = "Server" _
)

    If sListCode = "" Then sListCode = sListKey
    
    m_sListKey = sListKey
    m_sListCode = sListCode
    m_sRoleName = sRoleName
    m_sServerOrClientMode = sServerOrClientMode
    If m_sServerOrClientMode = "" Then m_sServerOrClientMode = "Server"
    
    Set m_SysData = SysData
    Set m_ctl = ctl
    Select Case ctl.ControlType
    Case acComboBox:
        m_sControlType = "ComboBox"
        Set m_cmb = ctl
        m_cmb.AfterUpdate = "[Event Procedure]"
    Case acListBox:
        m_sControlType = "ListBox"
        Set m_lst = ctl
        m_lst.AfterUpdate = "[Event Procedure]"
    End Select
    
    LoadData
    
End Function

'
'   Перехват событий аксесовских контролов для обработки своей логикой
'
Private Sub m_cmb_AfterUpdate()

    m_SysData.ApplyWhere Me.ListKey, Me.ListValue, Me.Where, Me.ListIndex, Me.ListCount, Me.ListData
    '    Запуск собственного события
    RaiseEvent ApplyWhere(Me.ListValue, Me.Where, Me.ListIndex, Me.ListCount, Me.ListData)

End Sub

Private Sub m_lst_AfterUpdate()

    m_SysData.ApplyWhere Me.ListKey, Me.ListValue, Me.Where, Me.ListIndex, Me.ListCount, Me.ListData
    '    Запуск собственного события
    RaiseEvent ApplyWhere(Me.ListValue, Me.Where, Me.ListIndex, Me.ListCount, Me.ListData)

End Sub