Private Sub cmdSend_Click()
'Есть база данных Банк, в ней есть таблица Депозитные счета, _
    поля номер счета и остаток средств, можно ли как то создать запрос или функцию _
    для кнопки, чтобы можно было вводить номер отправителя(счета), _
    сумму, а также получателя. _
    Если возможно сделать проверку, хватает ли средств на счету отправителя.
'--------------------------------------------------------------------------
Dim rstSRS As DAO.Recordset
Dim rstDST As DAO.Recordset

Dim sAccSRS As String, sAccDST As String, cSum As Currency
Dim s As String, v As Variant, c As Currency
'--------------------------------------------------------------------------
'берём данные из тек. формы
    
'es 24.12.2018
'
'--------------------------------------------------------------------------
On Error GoTo cmdSend_Click_Err
    sAccSRS = Me!txtCчетИсходный & ""  'Откуда
    sAccSRS = Replace(sAccSRS, " ", "") 'маска ввода с пробелами!
    sAccDST = Me!txtCчетНазначения & "" 'Куда
    sAccDST = Replace(sAccDST, " ", "") 'маска ввода с пробелами!
    
    cSum = Me!txtСумма
    
'Проверка 01
    
    s = "[№ счета]='" & sAccSRS & "'" 'Текстовый!
    v = DLookup("[№ счета]", "[Депозитные счета]", s)
    
    If IsNull(v) = True Then
        MsgBox "Исходный счёт: " & sAccSRS & " - не существует!", vbExclamation
        Me!txtCчетИсходный.SetFocus
        Exit Sub
    End If
    
'Проверка 02
    s = "[№ счета]='" & sAccDST & "'" 'Текстовый!
    v = DLookup("[№ счета]", "[Депозитные счета]", s)
    If IsNull(v) = True Then
        MsgBox "Счёт назначения: " & sAccDST & " - не существует!", vbExclamation
        Me!txtCчетНазначения.SetFocus
        Exit Sub
    End If
    
'Проверка 03
    If sAccSRS = sAccDST Then
        MsgBox "Исходный счёт и Счёт назначения совпадают!", vbExclamation
        Me!txtCчетНазначения.SetFocus
        Exit Sub
    End If
    
'Проверка 04
    If cSum = 0 Then
        MsgBox "Сумма не указана!", vbExclamation
        Me!txtСумма.SetFocus
        Exit Sub
    End If
        
'Проверка 05
    s = "[№ счета]='" & sAccSRS & "'" 'Текстовый!
    v = DLookup("[Остаток средств]", "[Депозитные счета]", s)
    c = CCur(Nz(v, 0)) - cSum
    If c < 0 Then
        MsgBox "На Исходном счёте не достаточно средств!", vbExclamation
        Me!txtСумма = CCur(Nz(v, 0))
        Me!txtСумма.SetFocus
        Exit Sub
    End If
'--------------------------------------------------------------------------
'Поехали!
    'Поступление
    s = "SELECT * FROM [Депозитные счета] WHERE [№ счета]='" & sAccDST & "'"
    Set rstDST = CurrentDb.OpenRecordset(s, dbOpenDynaset)
    
    'Списание
    s = "SELECT * FROM [Депозитные счета] WHERE [№ счета]='" & sAccSRS & "'"
    Set rstSRS = CurrentDb.OpenRecordset(s, dbOpenDynaset)
    
    If rstDST.EOF = True Or rstSRS.EOF = True Then
        MsgBox "Ошибка данных! - Операция не возможна", vbExclamation
        Exit Sub
    End If
    
    'Поступление на счёт назначения
    With rstDST
        .Edit
        c = ![Остаток средств] + cSum
        ![Остаток средств] = c
        .Update
    End With

    'Списание с исходного
    With rstSRS
        .Edit
        c = ![Остаток средств] - cSum
        ![Остаток средств] = c
        .Update
    End With

   DoCmd.Close acForm, Me.Name

cmdSend_Click_End:
    On Error Resume Next
    rstSRS.Close
    Set rstSRS = Nothing
    rstDST.Close
    Set rstDST = Nothing
    Err.Clear
    Exit Sub

cmdSend_Click_Err:
    MsgBox "Error: " & Err.Number & vbCrLf & Err.Description & vbCrLf & _
    "in Sub: cmdSend_Click in module: Form_Депозитные_счета_перевод", vbCritical, "Error in Application"
    Resume cmdSend_Click_End

End Sub