' From Access 2002 Desktop Developer's Handbook
' by Litwin, Getz, and Gunderloy (Sybex)
' Copyright 2001. All Rights Reserved.
    
Option Compare Database
Option Explicit

Function CreateTableFromRecordset( _
 rngAny As Word.Range, _
 rstAny As ADODB.Recordset, _
 Optional fIncludeFieldNames As Boolean = False) _
 As Word.Table

    Dim objTable As Word.Table
    Dim fldAny As ADODB.Field
    Dim varData As Variant
    Dim strBookmark As String
    Dim cField As Long

    ' Get the data from the recordset
    varData = rstAny.GetString()
    
    ' Create the table
    With rngAny
    
        ' Creating the basic table is easy,
        ' just insert the tab-delimted text
        ' add convert it to a table
        .InsertAfter varData
        Set objTable = .ConvertToTable()
        
        ' Field names are more work since
        ' you must do them one at a time
        If fIncludeFieldNames Then
            With objTable
            
                ' Add a new row on top and make it a heading
                .Rows.Add(.Rows(1)).HeadingFormat = True
                
                ' Iterate through the fields and add their
                ' names to the heading row
                For Each fldAny In rstAny.Fields
                    cField = cField + 1
                    .Cell(1, cField).Range.Text = fldAny.Name
                Next
            End With
        End If
    End With
    Set CreateTableFromRecordset = objTable
End Function

Sub PrintInvoiceWithWord(frmOrder As Form_Orders)
    Dim objWord As Word.Application
    Dim rst As Recordset
    Dim strSQL As String
    
    ' Launch Word and load the invoice template
    Set objWord = New Word.Application
    objWord.Documents.Add _
     Application.CurrentProject.Path & "\Invoice.dot"
    objWord.Visible = True
    
    ' Add header information using predefined bookmarks
    With objWord.ActiveDocument.Bookmarks
        .Item("OrderID").Range.Text = frmOrder.OrderID
        .Item("OrderDate").Range.Text = frmOrder.OrderDate
        .Item("CompanyName").Range.Text = frmOrder.CompanyName
        .Item("Address").Range.Text = frmOrder.Address
        .Item("Address2").Range.Text = frmOrder.City & ", " & _
         frmOrder.Region & " " & frmOrder.Country & " " & _
         frmOrder.PostalCode
    End With
    
    ' Build SQL string for details
    strSQL = "SELECT [Product Name], [Unit Price], Quantity, " & _
     "Disc, Extended FROM [Order Details Formatted] " & _
     "WHERE OrderID = " & frmOrder.OrderID
    
    ' Get details from database and create a table
    ' in the document
    Set rst = New Recordset
    rst.Open strSQL, CurrentProject.Connection
    With CreateTableFromRecordset( _
     objWord.ActiveDocument.Bookmarks("Details").Range, rst, True)
     
        ' Add rows for subtotal, freight, total
        With .Rows.Add
            .Cells(1).Range.Text = "Subtotal"
            .Cells(5).Range.Text = _
             FormatCurrency(frmOrder.Subtotal)
        End With
        With .Rows.Add
            .Cells(1).Range.Text = "Freight"
            .Cells(5).Range.Text = _
             FormatCurrency(frmOrder.Freight)
        End With
        With .Rows.Add
            .Cells(1).Range.Text = "Total"
            .Cells(5).Range.Text = _
             FormatCurrency(frmOrder.Total)
        End With
        
        ' Apply formatting
        .AutoFormat wdTableFormatProfessional
        .AutoFitBehavior wdAutoFitContent
        
        ' Fix up paragraph alignment
        .Range.ParagraphFormat.Alignment = wdAlignParagraphRight
        .Columns(1).Select
        objWord.Selection.ParagraphFormat.Alignment = wdAlignParagraphLeft
        objWord.Selection.MoveDown
    End With
    
    ' We're done
    Set objWord = Nothing
End Sub