Следующая программа изменяет в таблице "Сотрудники" название должности всех коммерческих представителей. После запуска с помощью метода BeginTrans транзакции, в которой выделяются все изменения, вносимые в таблицу "Сотрудники", метод CommitTrans вызывается для сохранения изменений. Отметим, что метод Rollback позволяет отменить все изменения, занесенные с помощью метода Update. Более того, главная транзакция является вложенной в другую транзакцию, которая автоматически отменяет любые изменения, внесенные пользователем при работе с данным примером.

Пока пользователь решает, стоит или нет сохранять изменения, одна или несколько страниц таблицы остаются заблокированными. Поэтому данный прием не может быть рекомендован для использования и приводится только для иллюстрации.

Sub BeginTransX()

Dim strName As String
Dim strMessage As String
Dim wrkDefault As Workspace
Dim dbsNorthwind As Database
Dim rstEmployees As Recordset

' Определяет стандартный объект Workspace.
Set wrkDefault = DBEngine.Workspaces(0)
Set dbsNorthwind = OpenDatabase("Борей.mdb")
Set rstEmployees = _
dbsNorthwind.OpenRecordset("Сотрудники")

' Запускает внешнюю транзакцию.
wrkDefault.BeginTrans
' Запускает главную транзакцию.

wrkDefault.BeginTrans

With rstEmployees

' Выполняет цикл по набору записей и спрашивает пользователя,
' следует ли изменять должность конкретного сотрудника.
Do Until .EOF
If !Должность = "Коммерческий представитель" Then
strName = !Фамилия & ", " & !Имя
strMessage = "Сотрудник: " & strName & vbCr & _
"Изменение должности"

' Изменяет должность указанного сотрудника.
If MsgBox(strMessage, vbYesNo) = vbYes Then

.Edit
!Должность = "Счетовод"
.Update
End If
End If

.MoveNext
Loop

' Запрашивает пользователя, следует ли занести
' все ранее сделанные изменения.
If MsgBox("Сохранить все изменения?", vbYesNo) = vbYes Then
wrkDefault.CommitTrans
Else
wrkDefault.Rollback
End If

' Печатает текущие данные из набора записей.
.MoveFirst
Do While Not .EOF
Debug.Print !Фамилия & ", " & !Имя & _

" - " & !Должность
.MoveNext
Loop

' Отменяет все изменения, внесенные пользователем,
' поскольку программа предназначена только для демонстрации.
wrkDefault.Rollback
.Close
End With

dbsNorthwind.Close

End Sub