Syntax
Scalar Functions

CREATE  FUNCTION [ owner_name. ] function_name 
    ( [ { @parameter_name [AS] scalar_parameter_data_type [ = default ] } [ ,...n ] ] ) 

RETURNS scalar_return_data_type

[ WITH < function_option> [ [,] ...n] ] 

[ AS ]

BEGIN 
    function_body 
    RETURN scalar_expression
END

Examples
A. Scalar-valued user-defined function that calculates the ISO week
In this example, a user-defined function, ISOweek, takes a date argument and calculates the ISO week number.  For this function to calculate properly, SET DATEFIRST  1  must be invoked before the function is called. 

CREATE FUNCTION ISOweek  (@DATE datetime)
RETURNS int
AS
BEGIN
   DECLARE @ISOweek int
   SET @ISOweek= DATEPART(wk,@DATE)+ 1 
      -DATEPART(wk,CAST(DATEPART(yy,@DATE) as CHAR( 4 ))+'0104')
 --Special cases: Jan 1-3 may belong to the previous year
 
   IF (@ISOweek= 0 ) 
      SET @ISOweek=dbo.ISOweek(CAST(DATEPART(yy,@DATE)- 1  
         AS CHAR( 4 ))+'12'+ CAST( 24 +DATEPART(DAY,@DATE) AS CHAR( 2 )))+ 1 
 --Special case: Dec 29-31 may belong to the next year
 
   IF ((DATEPART(mm,@DATE)= 12 ) AND 
      ((DATEPART(dd,@DATE)-DATEPART(dw,@DATE))>=  28 ))
      SET @ISOweek= 1 
   RETURN(@ISOweek)
END