Ну вот примерчик функции для списка

Static Function Список_1(ctl As Variant, lngID As Long, lngRow _
As Long, lngCol As Long, intCode As Integer) As Variant
' Добавляет "(Все)" первым пунктом в список. Для списка или поля
' со списком допускается добавление пункта "(Все)" в различные
' столбцы с помощью свойства "Дополнительные сведения" (Tag).
' Допускается также отображение текста, отличного от "(Все)",
' путем добавления точки с запятой (;) и отображаемого текста.
' Например, значение "2;<Нет>" свойства "Дополнительные сведения"
' (Tag) приведет к отображению слова "<Нет>" во втором столбце списка.


Static dbs_1 As Database, rst_1 As Recordset
Static lngDisplayID_1 As Long
Static intDisplayCol_1 As Integer
Static strDisplayText_1 As String
Dim intSemiColon As Integer

On Error GoTo Err_ДобавлениеВсеВСписок
Select Case intCode
Case acLBInitialize
' Проверяет, не используется ли функция.
If lngDisplayID_1 <> 0 Then
MsgBox "Функция Список_1 уже" & _
"используется в другом элементе управления!"
Список_1 = False
Exit Function
End If

' Проверяет отображаемый столбец и выводит текст,
' заданный в свойстве "Дополнительные сведения" (Tag).
intDisplayCol_1 = 1
strDisplayText_1 = "Все"
If Not IsNull(ctl.Tag) Then
intSemiColon = InStr(ctl.Tag, ";")
If intSemiColon = 0 Then
intDisplayCol_1 = Val(ctl.Tag)
Else
intDisplayCol_1 = Val(Left(ctl.Tag, intSemiColon - 1))
strDisplayText_1 = Mid(ctl.Tag, intSemiColon + 1)
End If
End If

' Открывает набор записей, заданный
' в свойстве "Источник строк" (RowSource).
Set dbs_1 = CurrentDb()
Set rst_1 = dbs_1.OpenRecordset(ctl.RowSource, dbOpenSnapshot)

' Записывает и возвращает значение lngID для функции.
lngDisplayID_1 = Timer
Список_1 = lngDisplayID_1

Case acLBOpen
Список_1 = lngDisplayID_1

Case acLBGetRowCount
' Возвращает число строк в наборе записей.
rst_1.MoveLast
Список_1 = rst_1.RecordCount + 1

Case acLBGetColumnCount
' Возвращает число полей (столбцов) в наборе записей.
Список_1 = rst_1.Fields.Count

Case acLBGetColumnWidth
Список_1 = -1

Case acLBGetValue
If lngRow = 0 Then
If lngCol = intDisplayCol_1 - 1 Then
Список_1 = strDisplayText_1
Else
Список_1 = "(Все)": 'Null
End If
Else
rst_1.MoveFirst
rst_1.Move lngRow - 1
Список_1 = rst_1(lngCol)
End If
Case acLBEnd
lngDisplayID_1 = 0
rst_1.Close
End Select

Bye_ДобавлениеВсеВСписок:
Exit Function

Err_ДобавлениеВсеВСписок:
MsgBox Err.Description, 16, " Список_1"
Список_1 = False
Resume Bye_ДобавлениеВсеВСписок
End Function

В этом примере да. Есть пример для ADO, но не знаю, будет ли он работать под 97, писал по 2000

Вот для ADO под 2000
Function ListMDBs(fld As Control, id, row, col, Code)

Static c As New Collection
Static RN As New Collection
Dim key As String
Dim ReturnVal As Variant
Dim rs As ADODB.Recordset
Dim i As Integer, j As Integer
On Error GoTo LErr:
ReturnVal = True
key = fld.Parent.name & fld.name

Select Case Code
Case acLBInitialize
Set rs = dbs.Execute(fld.RowSource)
rs.MoveFirst
c.Add rs, key
RN.Add 0, key
Case acLBOpen

Case acLBGetRowCount
Set rs = c(key)
ReturnVal = rs.RecordCount
Case acLBGetColumnCount
Set rs = c(key)
ReturnVal = rs.Fields.Count
Case acLBGetColumnWidth
ReturnVal = -1
Case acLBGetValue
Set rs = c(key)
If RN(key) <> row Then
rs.Move row - RN(key)
RN.Remove key
RN.Add row, key
End If
ReturnVal = rs.Fields(col).value
Case acLBEnd
c.Remove (key)
RN.Remove (key)
End Select
ListMDBs = ReturnVal
LErr:
If Err.Number <> 0 Then
Exit Function
End If
End Function