Function CBToolbarShow(strCBarName As String, _
                       blnVisible As Boolean, _
                       Optional lngPosition As Long = msoBarTop) As Boolean
                  
    ' This procedure displays or hides the command bar specified in the 
    ' strCBarName argument according to the value of the blnVisible 
    ' argument. The optional lngPosition argument specifies where the 
    ' command bar will appear on the screen. 
   
   Dim cbrCmdBar As CommandBar
      
   On Error GoTo CBToolbarShow_Err
   
   Set cbrCmdBar = Application.CommandBars(strCBarName)
   
    ' Show only toolbars. 
   If cbrCmdBar.Type > msoBarTypeNormal Then
      CBToolbarShow = False
      Exit Function
   End If
    ' If Position argument is invalid, set to the default 
    ' msoBarTop position. 
   If lngPosition < msoBarLeft Or lngPosition > msoBarMenuBar Then
      lngPosition = msoBarTop
   End If
   
   With cbrCmdBar
      .Visible = blnVisible
      .Position = lngPosition
   End With
   
   CBToolbarShow = True

CBToolbarShow_End:
   Exit Function
CBToolbarShow_Err:
   CBToolbarShow = False
   Resume CBToolbarShow_End
End Function

Function CBDeleteCommandBar(strCBarName As String) As Boolean
   On Error Resume Next
   Application.CommandBars(strCBarName).Delete
End Function

Function CBPrintCBarInfo(strCBarName As String) As Variant
    ' This procedure prints (to the Debug window) information 
    ' about the command bar specified in the strCBarName argument 
    ' and information about each control on that command bar. 
   
   Dim cbrBar                     As CommandBar
   Dim ctlCBarControl             As CommandBarControl
   Const ERR_INVALID_CMDBARNAME   As Long =  5 
   
   On Error GoTo CBPrintCBarInfo_Err
   
   Set cbrBar = Application.CommandBars(strCBarName)
   
   Debug.Print "CommandBar: " & cbrBar.Name & vbTab & "(" _
      & CBGetCBType(cbrBar) & ")" & vbTab & "(" _
      & IIf(cbrBar.BuiltIn, "Built-in", "Custom") & ")"
   For Each ctlCBarControl In cbrBar.Controls
      Debug.Print vbTab & ctlCBarControl.Caption & vbTab & "(" _
         & CBGetCBCtlType(ctlCBarControl) & ")"
   Next ctlCBarControl

CBPrintCBarInfo_End:
   Exit Function
CBPrintCBarInfo_Err:
   Select Case Err.Number
      Case ERR_INVALID_CMDBARNAME
         CBPrintCBarInfo = "'" & strCBarName & _
            "' is not a valid command bar name!"
      Case Else
         CBPrintCBarInfo = "Error: " & Err.Number _
            & " - " & Err.Description
   End Select
   Resume CBPrintCBarInfo_End
End Function