Option Explicit 

Public Const LF_FACESIZE     As Long =  32 & 
Public Const OBJ_FONT        As Long =  6 & 

Public Type LOGFONT 
  lfHeight         As Long 
  lfWidth          As Long 
  lfEscapement     As Long 
  lfOrientation    As Long 
  lfWeight         As Long 
  lfItalic         As Byte 
  lfUnderline      As Byte 
  lfStrikeOut      As Byte 
  lfCharSet        As Byte 
  lfOutPrecision   As Byte 
  lfClipPrecision  As Byte 
  lfQuality        As Byte 
  lfPitchAndFamily As Byte 
  lfFaceName( 1  To LF_FACESIZE) As Byte 
End Type 

Public Declare Function GetCurrentObject Lib "gdi32" _ 
  (ByVal hdc As Long, ByVal uObjectType As Long) As Long 
' GetObject bp API переименована, чтобы не затеняла GetObject из VB. 
Public Declare Function GetObjectDC Lib "gdi32" Alias "GetObjectA" _ 
  (ByVal hObject As Long, ByVal nCount As Long, lpObject As Any) As Long 
Public Declare Function CreateFontIndirect Lib "gdi32" Alias "CreateFontIndirectA" _ 
  (lpLogFont As LOGFONT) As Long 
Public Declare Function SelectObject Lib "gdi32" _ 
  (ByVal hdc As Long, ByVal hObject As Long) As Long 
Public Declare Function TextOut Lib "gdi32" Alias "TextOutA" _ 
  (ByVal hdc As Long, ByVal x As Long, ByVal y As Long, _ 
   ByVal lpString As String, ByVal nCount As Long) As Long 
Public Declare Function DeleteObject Lib "gdi32" _ 
  (ByVal hObject As Long) As Long 

Public Sub DrawStr(ByVal hdc As Long, _ 
                   txt As String, _ 
                   ByVal curX As Long, ByVal curY As Long, _ 
                   ByVal angle As Long) 
  Dim hfnt As Long, hfntPrev As Long, lfont As LOGFONT 
  hfntPrev = GetCurrentObject(hdc, OBJ_FONT) 
  GetObjectDC hfntPrev, Len(lfont), lfont 
  lfont.lfEscapement = angle 
  lfont.lfOrientation = angle 
  hfnt = CreateFontIndirect(lfont) 
  hfntPrev = SelectObject(hdc, hfnt) 
  TextOut hdc, curX, curY, txt, Len(txt) 
  SelectObject hdc, hfntPrev 
  DeleteObject hfnt 
End Sub

Option Explicit 

Private angle As Long 

Private Sub Form_Load() 
  Me.ScaleMode = vbPixels 
  Me.AutoRedraw = True 
  Timer1.Interval =  120  
  Timer1.Enabled = True 
End Sub 

Private Sub Timer1_Timer() 
  angle = angle +  60  
  If angle >  3600  Then angle = angle -  3600  
  Me.Cls 
  DrawStr Me.hdc, "Крутим, как хотим", Me.ScaleWidth /  2 , Me.ScaleHeight /  2 , angle 
End Sub