local loForm
loForm = newobject("myfrm")
loForm.show( 1 )
return 


DEFINE CLASS myfrm AS form

	DataSession =  2 
	DoCreate = .T.
	Name = "myfrm"


	ADD OBJECT grd1 AS grd WITH ;
		ColumnCount =  1 , ;
		Left =  24 , ;
		Top =  24 , ;
		Name = "Grd1", ;
		Cmn1.Name = "Cmn1"
		
	PROCEDURE Load
		create cursor tt (t i)
		for i= 1  to  10 
			insert into tt values (i)
		endfor
		go top
		*messagebox('load')
	ENDPROC


enddefine


DEFINE CLASS grd AS grid
	MemberClassLibrary = "program_test.prg"
	MemberClass = "cmn"
	Height =  200 
	Width =  320 
	Name = "grd"

	procedure init
		for each loColumn in this.Columns
			with loColumn
				.removeObject("text1")
				.addObject("txt1", "txtGrd")
			endwith
		endfor
	endproc 
	
	PROCEDURE onheadclick
		lparameters toHeader
		messagebox('Кликнули по заголовку '+toHeader.Caption)
	ENDPROC
ENDDEFINE

define class cmn as column
	headerclass = "head"				
	headerclasslibrary = "program_test.prg"

  	procedure init
		*messagebox('ИНИТ КОЛОНКИ')
	endproc	
enddefine

define class head as header	
	caption   = ""	

	procedure click
		this.Parent.Parent.onHeadClick(this)
		return .t.
	endproc      
enddefine


define class txtGrd as textBox
	
	visible = .t.
	
	procedure dblClick
		messagebox("2 раза кликнули по текстбоксу")
	endproc
enddefine