SELECT distinct parent FROM &tn WHERE EMPTY(parent) INTO CURSOR (curTemp1) readwrite

DO WHILE _tally >  0 
	SELECT * FROM &tn WHERE parent in (SELECT parent FROM (curTemp1)) INTO CURSOR (curTemp2) readwrite
	INSERT INTO (this.scoupname) SELECT * FROM (curTemp2)
	SELECT distinct key as parent FROM (curTemp2) INTO CURSOR (curTemp1) readwrite
ENDDO 

CLOSE TABLES ALL

lcTestCursor = "CurTest"
CREATE CURSOR (lcTestCursor) (Kod I NULL, KodPar I NULL, Punkt C( 20 ), nLft I, nRgt I, nLev I)
INSERT INTO (lcTestCursor) (Kod, KodPar) VALUES ( 1 , .NULL.)
INSERT INTO (lcTestCursor) (Kod, KodPar) VALUES ( 2 , .NULL.)
INSERT INTO (lcTestCursor) (Kod, KodPar) VALUES ( 3 ,  1 )
INSERT INTO (lcTestCursor) (Kod, KodPar) VALUES ( 4 ,  1 )
INSERT INTO (lcTestCursor) (Kod, KodPar) VALUES ( 5 ,  3 )
INSERT INTO (lcTestCursor) (Kod, KodPar) VALUES ( 6 ,  5 )
INSERT INTO (lcTestCursor) (Kod, KodPar) VALUES ( 7 ,  5 )
INSERT INTO (lcTestCursor) (Kod, KodPar) VALUES ( 8 ,  5 )
INSERT INTO (lcTestCursor) (Kod, KodPar) VALUES ( 9 ,  2 )
INSERT INTO (lcTestCursor) (Kod, KodPar) VALUES ( 10 ,  2 )
INSERT INTO (lcTestCursor) (Kod, KodPar) VALUES ( 11 ,  10 )
INSERT INTO (lcTestCursor) (Kod, KodPar) VALUES ( 12 ,  10 )
INSERT INTO (lcTestCursor) (Kod, KodPar) VALUES ( 13 ,  2 )
INSERT INTO (lcTestCursor) (Kod, KodPar) VALUES ( 14 ,  11 )
INSERT INTO (lcTestCursor) (Kod, KodPar) VALUES ( 15 ,  11 )
INSERT INTO (lcTestCursor) (Kod, KodPar) VALUES ( 16 ,  15 )
lnResult = BuildHierarhyIdx(.NULL.,  0 ,  0 , "Kod", "KodPar")
*-* (IGEL)  1 . 1  Строим иерархию...
IF lnResult != RECCOUNT()* 2 
	=MESSAGEBOX("ERROR1",  0 + 16 , "ERROR")
	RETURN .F.
ENDIF
INDEX ON nLft TO SYS( 2015 )
GO TOP
*-* (IGEL)  1 . 2  Обход дерева (для построения дерева стек уже не нужен).
LOCAL lcKey, lnLev
lcKey = ""
lnLev =  0 
SCAN	
	DO CASE
		CASE lnLev < nLev AND !ISNULL(KodPar)
			lcKey = lcKey + TRANSFORM(KodPar) + "."
		CASE lnLev > nLev AND !EMPTY(lcKey) 
			IF nLev >  1 
				lcKey = LEFT(lcKey, AT(".", lcKey, nLev -  1 ))
			ELSE
				lcKey = ""
			ENDIF				
	ENDCASE
	lnLev = nLev
	REPLACE Punkt WITH lcKey + TRANSFORM(Kod)
ENDSCAN

GO TOP
BROWSE LAST NOWAIT

FUNCTION BuildHierarhyIdx
	***********************************************************
	* Строим иерархию в текущем курсоре.
	LPARAMETERS tuNode, tnCounter, tnLevel, tcKeyField, tcParField

	PRIVATE ALL
	LOCAL lcOldAlias, lcNewAlias, lcIndex

	tnLevel		= tnLevel +  1 
	lcOldAlias	= ALIAS()
	lcNewAlias	= SYS( 2015 )
	lcIndex		= SYS( 2015 )
	*-* (IGEL)  1 . Строим индексы
	USE (DBF(lcOldAlias)) IN  0  ALIAS (lcNewAlias) AGAIN

	SELECT (lcNewAlias)
	INDEX ON &tcKeyField TAG KeyVal OF &lcIndex FOR NVL(&tcKeyField!=&tcParField, .T.) ADDITIVE
	INDEX ON &tcParField TAG ParVal OF &lcIndex ADDITIVE
	lcUslovie = TEXTMERGE([!INDEXSEEK(<<tcParField>>, .F., "<<lcNewAlias>>", "KeyVal")])

	*-* (IGEL)  2 . Основной цикл по данным
	SELECT (lcOldAlias)
	SCAN FOR !INDEXSEEK(&tcParField, .F., lcOldAlias, "KeyVal")
		tnCounter = tnCounter +  1 
		REPLACE nLft WITH tnCounter, ;
				nLev WITH tnLevel
		
		IF INDEXSEEK(&tcKeyField, .F., lcOldAlias, "ParVal")
			tnCounter = BuildHierarhyIdx_Iterate(&tcKeyField, tnCounter, tnLevel, lcOldAlias, tcKeyField, tcParField)
		ENDIF
				
		tnCounter = tnCounter +  1 
		REPLACE nRgt WITH tnCounter
	ENDSCAN

	*-* (IGEL)  3 . Вычищаем нами же построенные индексы
	USE IN SELECT(lcNewAlias)
	DELETE TAG KeyVal OF (lcIndex)
	DELETE TAG ParVal OF (lcIndex)
	TRY
		IF FILE(FORCEEXT(lcIndex, "CDX"))
			ERASE (FORCEEXT(lcIndex, "CDX"))
		ENDIF
	CATCH	
	ENDTRY

	RETURN tnCounter
ENDFUNC

FUNCTION BuildHierarhyIdx_Iterate
	LPARAMETERS tuNode, tnCounter, tnLevel, tcAlias, tcKeyField, tcParField
	LOCAL lnSaveRec
	lnSaveRec	= RECNO()
	IF tnCounter > RECCOUNT() *  2 
		=MESSAGEBOX(TEXTMERGE("Алгоритм BuildHierarhyIdx_Iterate зациклился на <<ALIAS()>>"),  0 + 16 , "Error")
		RETURN tnCounter
	ENDIF
	tnLevel		= tnLevel +  1 
	SCAN FOR &tcParField = tuNode
		IF NVL(&tcKeyField = &tcParField, .F.)
			LOOP
		ENDIF
		tnCounter = tnCounter +  1 
		REPLACE nLft WITH tnCounter, ;
				nLev WITH tnLevel
		
		IF INDEXSEEK(&tcKeyField, .F., tcAlias, "ParVal")
			tnCounter = BuildHierarhyIdx_Iterate(&tcKeyField, tnCounter, tnLevel, tcAlias, tcKeyField, tcParField)
		ENDIF
				
		tnCounter = tnCounter +  1 
		REPLACE nRgt WITH tnCounter
	ENDSCAN
	GOTO lnSaveRec
	RETURN tnCounter
ENDFUNC