with this
	local lnUpdatedRecn, lnOldRecNo
	if !deleted(.Alias)
		lnOldRecNo = recno(.Alias)
	else
		skip in (.Alias)
		if !bof(.Alias)
			lnOldRecNo = recno(.Alias)
		else
			skip - 1  in (.Alias)
			lnOldRecNo = recno(.Alias)
		endif 	
	endif
	if lnOldRecNo< 0 
		.BeforeCursorRefresh()
	endif 
	lnUpdatedRecn = .getModified()
	if !empty(lnUpdatedRecn) && в курсоре что-то потрогали
		local lnSqlTranOld, llSuccess, laErrors[ 1 ], lcOldStatusBar
		lcOldStatusBar = _vfp.StatusBar
		_vfp.StatusBar = 'Ждите ... Происходит обновление данных на сервере ...'
		if !.lLockTransactions
			lnSqlTranOld = sqlgetprop(.nConnection, "Transactions")
			llSuccess    = (sqlsetprop( .nConnection, "Transactions",  2 )= 1 )
		else
			llSuccess    = .t.
		endif
		if llSuccess
			.cError = ""
			if !.lCascad
				* обновление всего курсора кучей
				local laUpdErrArray[ 1 ]
				if !tableupdate(  2 , !empty(.nForceUpdate), .Alias, laUpdErrArray)
					=aerror(laErrors)
					text to .cerror noshow textmerge pretext  3 
						Курсорадаптер. Ошибка группового обновления.
						
						Не обновлено <<str(alen(laUpdErrArray,  1 ))>>  записей.
					endtext
					llSuccess = .f.
				endif
			else
				* Обновление каскадов
				* Обновляем последовательно все измененные записи в курсоре
				do while !empty(lnUpdatedRecn)
					go (lnUpdatedRecn) in .alias
					if !.updateRecord(@laErrors)
					    llSuccess = .f.
					    exit
					endif
					lnUpdatedRecn = getNextModified(lnUpdatedRecn,.alias)
					if empty(lnUpdatedRecn)
						exit
					endif    
				enddo
			endif
			if !llSuccess
				* ошибка, не смогли сохранить изменения на сервер
				if !.lLockTransactions
					=sqlrollback(.nConnection)
					=sqlsetprop( .nConnection, "Transactions", lnSqlTranOld)
				endif
				_vfp.StatusBar = ""
				local lcErrMessage
				text to lcErrMessage textmerge noshow pretext  3 
					Курсорадаптер. Ошибка сохранения изменений в таблице <<.Tables>>.
					
					Ошибка: <<iif(alen(laErrors)>= 2 ,laErrors[ 2 ],'Ошибка не идентифицирована.')>>
					<<iif(!empty(.cError), "Доп.информация: " + .cError, "")>>
				endtext
				=messagebox(lcErrMessage, 16 ,'Класс КАД')
				return .f.
			else
				* все хорошо, сохранились
				if !.lLockTransactions
					=sqlcommit(.nConnection)
				endif
			endif
		else
			_vfp.StatusBar = 'КАД. Ошибка выполнения транзакции на сервере.'
			return .f.
		endif
		if !.lLockTransactions
			* восстанавливаем состояние
			=sqlsetprop( .nConnection, "Transactions", lnSqlTranOld)
		endif
		_vfp.StatusBar = lcOldStatusBar  &&'КАД. Данные на сервере обновлены успешно.'
	else
		* в курсоре ничего не трогали - нечего обновлять на сервере
		return .t.
	endif
	select (.Alias)
	if lnOldRecNo> 0  and recno(.Alias)<>lnOldRecNo
		locate record lnOldRecNo
	else
		if lnOldRecNo< 0 
			.AfterCursorRefresh()
		else
			go top
		endif
	endif
endwith 
return .t.