********************************************************************************
LOCAL lfrmMain
lfrmMain = CREATEOBJECT('MyForm')
lfrmMain.Show( 1 )

CLOSE TABLES

********************************************************************************
DEFINE CLASS MyForm AS Form 
	
	Caption     = 'Связанные таблицы.'
	BorderStyle =  2 
	
	ADD OBJECT grdParent AS Grid WITH          ;
		Left               =  5 ,            ;
		Top                =  5 ,            ;
		Width              =  250 ,          ;
		Height             =  250 ,          ;
		AllowCellSelection = .F.,          ;
		RecordSource       = 'ParentTable'
		
	ADD OBJECT grdChild AS Grid WITH           ;
		Top                =  5 ,            ;
		Width              =  250 ,          ;
		Height             =  250 ,          ;
		AllowCellSelection = .F.,          ;
		RecordSource       = 'ChildTable'
		 
	ADD OBJECT chkMode AS MyCheckBox WITH  ;
		Left    =  5 ,                   ;
		Height  =  25 ,                  ;
		Value   = .F.,                 ;
		Caption = 'Отображать как связанные.'
		
	PROCEDURE Load
	
		SELECT  0 
		IF FILE('ParentTable.dbf')
			
			USE 'ParentTable.dbf'
			
		ELSE 
			
			CREATE DBF 'ParentTable.dbf' ( ;
				Field1 Character,      ;
				Field2 Character,      ;
				Id     Integer AUTOINC ;
			)
			
			INSERT INTO 'ParentTable' (Field1, Field2) VALUES('1', '1')
			INSERT INTO 'ParentTable' (Field1, Field2) VALUES('1', '2')
			INSERT INTO 'ParentTable' (Field1, Field2) VALUES('1', '3')
			INSERT INTO 'ParentTable' (Field1, Field2) VALUES('2', '1')
			INSERT INTO 'ParentTable' (Field1, Field2) VALUES('2', '2')
			
		ENDIF && FILE('ParentTable.dbf')

		SELECT  0 
		IF FILE('ChildTable.dbf')
			
			USE 'ChildTable.dbf'
			
		ELSE 
			
			CREATE DBF 'ChildTable.dbf' (  ;
				Field1 Character,      ;
				Field2 Character,      ;
				Id     Integer AUTOINC ;
			)
			
			INSERT INTO 'ChildTable' (Field1, Field2) VALUES('1', '1')
			INSERT INTO 'ChildTable' (Field1, Field2) VALUES('1', '1')
			INSERT INTO 'ChildTable' (Field1, Field2) VALUES('1', '2')
			INSERT INTO 'ChildTable' (Field1, Field2) VALUES('2', '1')
			INSERT INTO 'ChildTable' (Field1, Field2) VALUES('2', '1')
			INSERT INTO 'ChildTable' (Field1, Field2) VALUES('1', '1')
			
		ENDIF && FILE('ChildTable.dbf')

		IF FILE('ChildTable.idx')
			
			SET INDEX TO 'ChildTable.idx'
			
		ELSE 
			
			INDEX ON Field1 + Field2 TO 'ChildTable.idx'
			
		ENDIF && FILE('ChildTable.idx')
		
	ENDPROC && Load
	
	PROCEDURE Unload
		
		CLOSE TABLES 
		
	ENDPROC && Unload 
	
	PROCEDURE Init
		
		This.grdChild .Left = This.grdParent.Width +  10 
		
		This.Width = This.grdChild .Left + This.grdChild .Width +  5 

		This.chkMode.Top   = This.grdParent.Height +  10 
		This.chkMode.Width = This.Width -  10 
		
		This.Height = This.chkMode.Top + This.chkMode.Height +  5 
		
	ENDPROC && Init
	
ENDDEFINE && CLASS MyForm

********************************************************************************
DEFINE CLASS MyCheckBox AS CheckBox  
	
	PROCEDURE InteractiveChange 
		
		SELECT ParentTable 
		
		IF This.Value 
			
			SET RELATION TO Field1 + Field2 INTO ChildTable
		
		ELSE 
			
			SET RELATION OFF INTO ChildTable
			
		ENDIF && This.Value 
		
	ENDPROC && Click
	
ENDDEFINE && MyCheckBox 

DEFINE CLASS MyCheckBox AS CheckBox  
	
	PROCEDURE InteractiveChange 

DEFINE CLASS MyCheckBox AS CheckBox  
	
	PROCEDURE VALID