* Reading STARTUPINFO structure for the current VFP session
Do Declare

*| typedef struct _STARTUPINFO {
*|   DWORD   cb;                 4 
*|   LPTSTR  lpReserved;         4 
*|   LPTSTR  lpDesktop;          4 
*|   LPTSTR  lpTitle;            4 
*|   DWORD   dwX;                4 
*|   DWORD   dwY;                4 
*|   DWORD   dwXSize;            4 
*|   DWORD   dwYSize;            4 
*|   DWORD   dwXCountChars;      4 
*|   DWORD   dwYCountChars;      4 
*|   DWORD   dwFillAttribute;    4 
*|   DWORD   dwFlags;            4 
*|   WORD    wShowWindow;        2 
*|   WORD    cbReserved2;        2 
*|   LPBYTE  lpReserved2;        4 
*|   HANDLE  hStdInput;          4 
*|   HANDLE  hStdOutput;         4 
*|   HANDLE  hStdError;          4 
*| } STARTUPINFO, *LPSTARTUPINFO; total:  68  bytes

Local lcStartupInfo, lnAddr

* do not use SPACE( 250 ) instead; there must be strict zeroes
lcStartupInfo = Repli(Chr( 0 ),  250 )

= GetStartupInfo(@lcStartupInfo)

? "Byte size:", buf2dword(Substr(lcStartupInfo,  1 , 4 ))
? "lpReserved:", buf2dword(Substr(lcStartupInfo,  5 , 4 ))

* WinNT/XP/@K returns a string value; WinMe -- empty string
? "lpDesktop string:", getStr(buf2dword(Substr(lcStartupInfo,  9 , 4 )))

* WinNT/XP/2K: possibly the shortcut to your VFP application
* or a full path to the executable if started directly
* WinMe = empty string
lcShortcut = getStr(buf2dword(Substr(lcStartupInfo,  13 , 4 )))

Return Getwordnum(lcShortcut, Getwordcount(lcShortcut, [\]), [\])

*!*	? "lpTitle string:", lcShortcut

*!*	? "dwX:", buf2dword(Substr(lcStartupInfo,  17 , 4 ))
*!*	? "dwY:", buf2dword(Substr(lcStartupInfo,  21 , 4 ))
*!*	? "dwXSize:", buf2dword(Substr(lcStartupInfo,  25 , 4 ))
*!*	? "dwYSize:", buf2dword(Substr(lcStartupInfo,  29 , 4 ))
*!*	? "dwXCountChars:", buf2dword(Substr(lcStartupInfo,  33 , 4 ))
*!*	? "dwYCountChars:", buf2dword(Substr(lcStartupInfo,  37 , 4 ))
*!*	? "dwFillAttribute:", buf2dword(Substr(lcStartupInfo,  41 , 4 ))
*!*	? "dwFlags:", buf2dword(Substr(lcStartupInfo,  45 , 4 ))
*!*	? "wShowWindow:", buf2word(Substr(lcStartupInfo,  49 , 2 ))
*!*	? "cbReserved2:", buf2word(Substr(lcStartupInfo,  51 , 2 ))
*!*	? "lpReserved2:", buf2dword(Substr(lcStartupInfo,  53 , 4 ))
*!*	? "hStdInput:", buf2dword(Substr(lcStartupInfo,  57 , 4 ))
*!*	? "hStdOutput:", buf2dword(Substr(lcStartupInfo,  61 , 4 ))
*!*	? "hStdError:", buf2dword(Substr(lcStartupInfo,  65 , 4 ))

Function num2dword(lnValue)
   #Define m0 0x0000100
   #Define m1 0x0010000
   #Define m2 0x1000000
   If lnValue <  0 
      lnValue = 0x100000000 + lnValue
   Endif
   Local b0, b1, b2, b3
   b3 = Int(lnValue/m2)
   b2 = Int((lnValue - b3*m2)/m1)
   b1 = Int((lnValue - b3*m2 - b2*m1)/m0)
   b0 = Mod(lnValue, m0)
   Return Chr(b0)+Chr(b1)+Chr(b2)+Chr(b3)

Function buf2dword(lcBuffer)
   Return Asc(Substr(lcBuffer,  1 , 1 )) + ;
      Asc(Substr(lcBuffer,  2 , 1 )) *  256  +;
      Asc(Substr(lcBuffer,  3 , 1 )) *  65536  +;
      Asc(Substr(lcBuffer,  4 , 1 )) *  16777216 

Function buf2word(lcBuffer)
   Return Asc(Substr(lcBuffer,  1 , 1 )) + ;
      Asc(Substr(lcBuffer,  2 , 1 )) *  256 

Function getStr(lnAddr)
   Local lcBuffer
   lcBuffer = Repli(Chr( 0 ),  128 )
   = CopyMemory(@lcBuffer, lnAddr, Len(lcBuffer))

   If At(Chr( 0 ), lcBuffer) <>  0 
      lcBuffer = Substr(lcBuffer,  1 , At(Chr( 0 ), lcBuffer)- 1 )
   Endif
   Return  lcBuffer

Procedure Declare
   Declare GetStartupInfo In kernel32 String @lpStartupInfo

   Declare RtlMoveMemory In kernel32 As CopyMemory  String @Destination, Integer Source, Integer nLength