func GetGUID
local lcRet, lcGuid, i
lcRet = ''
try
	lcGuid = repl(chr(0), 17)
	DECLARE INTEGER CoCreateGuid IN OLE32.DLL STRING @pGuid
	if CoCreateGuid(@lcGuid) = 0
		lcRet = ToHex(StrToLong(left(lcGuid, 4)), 8) + '-';
				+ ToHex(StrToLong(substr(lcGuid, 5, 2)), 4) + '-';
				+ ToHex(StrToLong(substr(lcGuid, 7, 2)), 4) + '-';
				+ ToHex(StrToLong(substr(lcGuid, 9, 2)), 4) + '-';
				+ ToHex(StrToLong(substr(lcGuid, 11, 4)), 8);
				+ ToHex(StrToLong(substr(lcGuid, 15, 2)), 4)
	endif
catch to oErr
	* вывод сообщения от ошибке oErr
	lcRet = ''
endtry
if empty(lcRet)
	lcRet = 'BAD-GUID-' + chrtran(ttoc(datetime()), '.: ', '---') + '-' + substr(sys(2015), 2)
endif
return lcRet

* Перевод в 16-ную систему счисления
func ToHex
lpara tnValue, tnDigit
local lcRet, lnCifra
lcRet=""
do while tnValue > 0
   lnCifra = tnValue % 16
   tnValue = int(tnValue / 16)
   if lnCifra < 10
      lcRet = chr(lnCifra + 48) + lcRet
   else
      lcRet = chr(lnCifra + 55) + lcRet
   endif
enddo
if !empty(tnDigit) and tnDigit != len(lcRet)
	lcRet = padl(lcRet, tnDigit, '0')
endif
return lcRet

func StrToLong
lpara tcLongStr
local i, lnRet
lnRet = 0
for i = 0 to 24 step 8
   lnRet = lnRet + (asc(tcLongStr) * (2^i))
   tcLongStr = right(tcLongStr, len(tcLongStr) - 1)
NEXT
RETURN lnRet