***frmCalc.cmgCalc.Click
LOCAL lcButton,loButton
lcButton = 'This.Command' + ALLTRIM(STR(THIS.VALUE))
loButton = &lcButton
THISFORM.DoCalc(loButton.CAPTION)

***frmCalc.DoCalc()
LPARAMETERS tcButton && 0...9,C,(=),<-,/,*,-,+,.,+/-,Enter - 19 êíîïîê
WITH THISFORM.txtDisplay
DO CASE
CASE tcButton == 'Enter'
LOCAL llSuccess
llSuccess = .T.
IF !EMPTY(.VALUE)
TRY
.VALUE = EVALUATE(.VALUE)
CATCH
MESSAGEBOX('Íåâåðíî ñîñòàâëåíî âûðàæåíèå')
.VALUE = ''
llSuccess = .F.
ENDTRY
ENDIF
IF llSuccess
.VALUE = TRANSFORM(.VALUE)
THIS.uRetval = THIS.txtDisplay.VALUE
THIS.RELEASE()
ENDIF

CASE tcButton == '(=)'
IF !EMPTY(.VALUE)
TRY
.VALUE = ALLTRIM(STR(EVALUATE(.VALUE)))
CATCH
MESSAGEBOX('Íåâåðíî ñîñòàâëåíî âûðàæåíèå')
.VALUE = ''
ENDTRY
ENDIF

CASE tcButton == 'C'
.VALUE = ''

CASE tcButton == '<-'
.VALUE = LEFT(.VALUE,LEN(.VALUE) - 1)

CASE tcButton == '+/-'
.VALUE = IIF(LEFT(.VALUE,1) = '-',''+ SUBSTR(.VALUE,2),'-' + .VALUE)

OTHERWISE
.VALUE = .VALUE + tcButton
ENDCASE
ENDWITH

***frmCalendar.opgDays.Click
THISFORM.DoDate('Day',THIS.VALUE)
***frmCalendar.cmgNavigate.Click
LOCAL lcButton,loButton
lcButton = 'This.Command' + ALLTRIM(STR(THIS.VALUE))
loButton = &lcButton
THISFORM.DoDate(loButton.CAPTION) && <<,<,Enter,>,>>
***frmCalendar.DoDate()
LPARAMETERS tcButton,tnDay
WITH THIS
DO CASE
CASE tcButton == 'Enter'
.uRetval = .txtDisplay.VALUE
.RELEASE()
CASE tcButton == '<<'
.dDate = GOMONTH(.dDate,-12)
CASE tcButton == '<'
.dDate = GOMONTH(.dDate,-1)
CASE tcButton == '>'
.dDate = GOMONTH(.dDate,+1)
CASE tcButton == '>>'
.dDate = GOMONTH(.dDate,+12)
CASE tcButton == 'Day'
.dDate = .dDate - DAY(.dDate) - DOW(.dDate-DAY(.dDate)) + tnDay + 1
ENDCASE
ldDate = .dDate

.opgDays.VALUE = DAY(ldDate) + DOW(ldDate-DAY(ldDate)) - 1
ldTemp = ldDate - .opgDays.VALUE
FOR i = 1 TO 42
ldTemp = ldTemp + 1
IF MONTH(ldTemp) = MONTH(ldDate)
.opgDays.BUTTONS[i].FONTSIZE = 8
*.opgDays.Buttons[i].FontBold = .T.
ELSE
.opgDays.BUTTONS[i].FONTSIZE = 5
*.opgDays.Buttons[i].FontBold = .F.
ENDIF
.opgDays.BUTTONS[i].CAPTION = ALLTRIM(STR(DAY(ldTemp)))
ENDFOR
.txtDisplay.VALUE = .dDate
ENDWITH