WITH CREATEOBJECT("Form_1")
  	.show(1)  
ENDWITH 
 DEFINE CLASS form_1 AS form  
    AutoCenter = .T.
  	Height     =  200  
  	Width      =  325  
  	Caption    = "Form_1"  
  	Name       = "Form_1"
    BackColor  = RGB(245,243,222)

 PROCEDURE Init 
*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*  LABEL
 This.AddObject('Label_1','Label')
 WITH This.Label_1
     .BackStyle= 0
     .Visible  = .T. 
     .TOP      = 10
     .LEFT     = 10
     .Height   = 20
     .Width    = 70
     .Alignment = 2
     .Caption  = 'Удаление'
 ENDWITH
 
*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~* CommandButton 1
 ThisForm.AddObject('com_1','CommandButton_1')
 WITH ThisForm.com_1
     .Caption = 'Удаление:'
     .Visible  = .T. 
     .TOP      = 10
     .LEFT     = 215
     .Height   = 20
     .Width    = 100
     .Default  = .F.
     .TabIndex = 0
     .TabStop  = .F.
 ENDWITH
 
*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*  GRID
 This.AddObject('Grid_1','Grid')
 WITH This.Grid_1
     .Height = 160
     .Width  = 315
     .AllowCellSelection = .F. 
     .TabIndex = 1
     .Top          =  35
     .Left         =  5
     .Visible      = .T. 
     .DeleteMark   = .F.
     .RecordMark   = .F.
     .ReadOnly     = .T.
     .ScrollBars   =  2
     .ColumnCount  =  2
     .HeaderHeight =  0
     .RecordSource = 'Table_1'
     .column1.ControlSource = 'Table_1.Nom' 
     .column2.ControlSource = 'Table_1.Date_' 
     .column1.width = 147
     .column2.width = 146
     .column1.Alignment = 6
     .column2.Alignment = 6
     .column1.Resizable = .F.
     .column2.Resizable = .F.
 ENDWITH
*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*
 ENDPROC
 
 PROCEDURE load
*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~* 
 CREATE CURSOR Table_1( Nom N(2), Date_ D(8))
   INSERT INTO Table_1 VALUES (1, DATE()+10)
   INSERT INTO Table_1 VALUES (2, DATE()+20)
   INSERT INTO Table_1 VALUES (3, DATE()+30)
   INSERT INTO Table_1 VALUES (4, DATE()+40)
   INSERT INTO Table_1 VALUES (5, DATE()+50)
   INSERT INTO Table_1 VALUES (6, DATE()+60)
   GO TOP
*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*
 ENDPROC
 ENDDEFINE

 *~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*
  DEFINE CLASS CommandButton_1 as CommandButton
  PROCEDURE click

  nAnswer = MESSAGEBOX('Удалить '+ALLTRIM(STR(Table_1.nom))+' и '+DTOC(date_)+' '+'?', 4+256, 'Внимание!')
  IF nAnswer=6     && Да
 *=========================================*
    SELECT Table_1
  IF .NOT. EOF()
    IF DELETED()= .T.
    RECALL
    WAIT 'Восстановлено!' WINDOW TIMEOUT 0.5
    ELSE
    DELETE
    WAIT 'Удалено!' WINDOW TIMEOUT 0.5
    ENDIF
  ELSE    
    WAIT 'Удаление не возможно' WINDOW NOWAIT
  ENDIF
 *=========================================*
  ENDIF
  ThisForm.Refresh
  ThisForm.grid_1.column1.SetFocus

  ENDPROC
 ENDDEFINE
*================================================================*