* Структура исходной таблицы
Local laNad_Dop(1)
Select nad_dop
=Afields(laNad_Dop)

* Структура создаваемой таблицы
Local laTnad_tabl(1,6), lnI, lnJ, lnZ
lnZ = 0
* Копирую в целевой массив структуру нужных полей
For lnI = 1 to Alen(laNad_Dop, 1)
	* В массиве имена полей в верхнем регистре
	If InList(laNad_Dop[m.lnI, 1], 'RID', 'HEADER', 'NORDER', 'USER_I', 'DATE_I', 'USER_U', 'DATE_U')
		lnZ = m.lnZ + 1
		Dimension laTnad_tabl(m.lnZ,6)
		For lnJ = 1 to 6
			laTnad_tabl[m.lnZ, m.lnJ] = laNad_Dop[m.lnI, m.lnJ]
		EndFor
	EndIf
EndFor

* Создаю структуру поля Change
lnZ = lnZ + 1
Dimension laTnad_tabl(m.lnZ,6)
laTnad_tabl[m.lnZ, 1] = 'Change'
laTnad_tabl[m.lnZ, 2] = 'N'
laTnad_tabl[m.lnZ, 3] = 1
laTnad_tabl[m.lnZ, 4] = 0
laTnad_tabl[m.lnZ, 5] = .F.
laTnad_tabl[m.lnZ, 6] = .F.

* Создаю структуру дополнительных полей
* Как поля с именем вида NAD1, NAD2, NAD3,...
* Количество которых равно количеству записей в таблице nad_dop

* Количество записей в таблице nad_dop
Local Array laRecords(1)
Select Count(*) from nad_dop into array laRecords

Local lcFieldName
For lnI = 1 to laRecords[1]
	lcFieldName = 'NAD' + ltrim(Str(m.lnI))
	lnZ = lnZ + 1
	Dimension laTnad_tabl(m.lnZ,6)
	laTnad_tabl[m.lnZ, 1] = m.lcFieldName
	laTnad_tabl[m.lnZ, 2] = 'N'
	laTnad_tabl[m.lnZ, 3] = 3
	laTnad_tabl[m.lnZ, 4] = 0
	laTnad_tabl[m.lnZ, 5] = .F.
	laTnad_tabl[m.lnZ, 6] = .F.
EndFor

* Создаю целевую таблицу
Create Table (g_temp+'tnad_tabl.dbf') FREE From Array laTnad_tabl

* Наполняю таблицу данными 
* Синтаксис корректен только для VFP9
* Для младших версий следует использовать APPEND FROM или SCAN + INSERT
Insert into tnad_tabl ;
	(RID, HEADER, NORDER, USER_I, DATE_I, USER_U, DATE_U) ;
Select ;
	RID, HEADER, NORDER, USER_I, DATE_I, USER_U, DATE_U ;
from nad_dop ;
order by nOrder

* Далее можно модифицировать поля NAD1, NAD2, NAD3,... сканируя уже созданую таблицу
Select tnad_tabl
Scan
	lcFieldName = 'NAD' + ltrim(Str(m.lnI))
	If (...)
		replace (m.lcFieldName) with ...
	Else
		replace (m.lcFieldName) with ...
	EndIf
EndScan