PROCEDURE DoBack(m.TimerName_yc)
LOCAL m.tmr_lo, m.frm_lo
CLEAR
m.tmr_lo = NEWOBJECT ('FatTimer')
IF PCOUNT () > 0
  ? 'PCOUNT', PCOUNT()
  m.tmr_lo.ObjName = m.TimerName_yc
ENDIF
PUBLIC m.Busy_gl, m.Stop_gl
STORE .F. TO m.Busy_gl, m.Stop_gl
m.tmr_lo.Enabled = .T.
? 'Ctrl+F12 for CLEAR EVENTS'
? TIME()
ON KEY LABEL CTRL+F12 DO StopDo
m.frm_lo = NEWOBJECT ('MyForm')
m.frm_lo.Left = _SCREEN.Width / 2
m.frm_lo.Visible = .T.
READ EVENTS
? TIME()
ON KEY LABEL CTRL+F12
ENDPROC && DoBack

PROCEDURE StopDo
ON KEY LABEL CTRL+F12
m.Stop_gl = .T.
CLEAR EVENTS
ENDPROC && StopDo

DEFINE CLASS FatTimer AS Timer
Interval = 100
Counter = 0
ObjName = 'FatTimer'

PROCEDURE Timer
*DOEVENTS
ACTIVATE SCREEN
IF NOT THIS.Enabled
  ? TIME(), STR(THIS.Counter,2), THIS.Enabled
  RETURN
ENDIF
? TIME(), STR(THIS.Counter,2), THIS.Enabled, THIS.ObjName
IF THIS.Counter < 99
  IF NOT m.Busy_gl
    THIS.Counter = THIS.Counter + 1
    ON KEY LABEL Ctrl+F11 DO BackGround
    KEYBOARD '{Ctrl+F11}' CLEAR && PLAIN
  ENDIF
ELSE
  THIS.Enabled = .F.
  ? TIME(), 'Stop', '', THIS.ObjName
  DOEVENTS
ENDIF
?? '', TIME(), 'FatTimer'
ENDPROC && Timer

ENDDEFINE && FatTimer

PROCEDURE BackGround
ON KEY LABEL Ctrl+F11
m.Busy_gl = .T.
ACTIVATE SCREEN
? TIME(), 'Back ini'
LOCAL m.StopTime_ln
m.StopTime_ln = SECONDS () + 3
DO WHILE SECONDS() < m.StopTime_ln AND NOT m.Stop_gl
  DOEVENTS
ENDDO
ACTIVATE SCREEN
?? '', TIME(), 'Back fin'
m.Busy_gl = .F.
ENDPROC && BackGround

DEFINE CLASS MyForm AS Form
ENDDEFINE && MyForm