*lcFileName =  имя файла, которое аттачим
*lcEmail = мыло, куда шлем

= snd(lcFileName, lcEmail)	



FUNCTION Snd 
LPARAMETERS lcFileName__, Email__

	lo=NEWOBJECT([SendMail])

	lo.Address=[smtp.gmail.com] && SMTP сервер
	lo.User=[...................................] && почтовый адрес пользователя для авторизации на сервисе
	lo.Password=[...................................] && пароль

	lo.SSL=1	    && использовать SSL
	lo.Port=465     && порт для SSL
	lo.Auth=1       && требуется аутентификация

	lo.From=[...................................] && от кого, e-mail
	lo.To  = ALLTRIM(Email__) && кому
	lo.CC  =[...................................] && доп копия, если нада

	lo.Subject=[...................................] && тема письма
	lo.Textbody=[.] && тело письма 

        lo.Files.Clear				&& при множественном использовании отправки файлов - очистка перед заполнением
        lo.Files.AddFile(lcFileName__) && аттачим файл для отправки

	*  lo.Compress=.T.					&& запакуем файлы перед отправкой
	lo.Compress=.F.					&& не упаковывать файло
	lo.Send

	RELEASE lo

RETURN 

**********************************************************************************************
DEFINE CLASS SendMail AS Session
	HIDDEN oCDO, oFSO, Schema
	oCDO  = .NULL.		&& объект для оправки сообщений
	oShell= .NULL.		&& объект для работы со сжатыми папками
	Files = .NULL.		&& коллекция прикрепляемых файлов
	Schema= [http://schemas.microsoft.com/cdo/configuration/]
	Compress=.F.		&& сжимать отправляемые вложения
	ZipFolder=[Attachment.zip]	&& имя сжатой папки с вложениями
	ZipInterval=0.1		&& 100 мс - частота опроса завершения архивирования
	
    From     = []		&& параметры отправителя (имя и адрес электронной почты)
	To       = []		&& адрес электронной почты получателя
	CC		 = []		&& походу копия кому еще слать
	Subject  = []		&& тема сообщения
	Textbody = []		&& текст сообщения
	Address  = []		&& адрес SMTP-сервера
	Port     = [25]		&& порт SMTP-сервера
	User     = []		&& имя пользователя для регистрации на сервере
	Password = []		&& пароль пользователя для регистрации на сервере
	Charset  = [windows-1251]	&& кодировка текста письма
	SSL      = 0		&& использование SSL
	Auth     = 0		&& аутентификация на сервере
	CTO      = 60		&& ConnectionTimeOut
	
	PROCEDURE Send
		this.oCDO=NEWOBJECT([CDO.Message])
		WITH this.oCDO						&& переопределим свойства для объекта CDO
		    .From     = this.From
			.To       = this.To
			.CC		  = this.CC
			.Subject  = this.Subject
			.BodyPart.Charset = this.Charset
			.Textbody = this.TextBody
			WITH .Configuration.Fields		&& настроим подключение
				.Item(this.Schema+"sendusing")     = 2             && Отправить сообщение используя сетевую SMTP-службу (1 - используется для отправки через локальную SMTP-службу)
				.Item(this.Schema+"laguagecode")   = [ru]
				.Item(this.Schema+"smtpserver")    = this.Address
				.Item(this.Schema+"smtpserverport")= this.Port
				.Item(this.Schema+"sendusername")  = this.User
				.Item(this.Schema+"sendpassword")  = this.Password
				.Item(this.Schema+"smtpusessl")            = this.SSL
				.Item(this.Schema+"smtpauthenticate")      = this.Auth
				.Item(this.Schema+"smtpconnectiontimeout") = this.CTO
				.Update                                       		&& Обновить конфигурацию CDO-объекта
			ENDWITH
			
			* если нужно сжать вложения
			IF this.Compress THEN
				IF this.ToZip() THEN
					.AddAttachment(FULLPATH(this.ZipFolder))
					.Send
				ENDIF				
				
			* если не нужно - прикрепляем все необходимые файлы
			ELSE
				FOR EACH lcFile IN this.Files
					.AddAttachment(m.lcFile)
				ENDFOR
				.Send
			ENDIF
			*-- и наконец отправляем
			*-- здесь мы не можем проконтролировать успешность отправки, как и сам ход оправки...
			*-- да это нам особенно и не нужно... системные сообщения будут выведены на экран...
*			.Send
			
		ENDWITH
		this.oCDO=.NULL.
	ENDPROC

	PROCEDURE ToZip
		this.oShell=NEWOBJECT([Shell.Application])
		LOCAL loError AS Exception
		DO WHILE FILE(this.ZipFolder)
			TRY
				DELETE FILE (this.ZipFolder)
			CATCH TO loError
				IF INKEY(this.ZipInterval)=27 AND 1=MESSAGEBOX([Файл ]+this.ZipFolder+[ не может быть удален]+CHR(13)+[Прервать?],1) THEN
					RETURN .F.
				ENDIF
			ENDTRY
		ENDDO
		
		* создадим пустой ZIP-файл
		STRTOFILE([PK]+PADR(CHR(5)+CHR(6),20,CHR(0)),this.ZipFolder)
		
		* поочередно добавляем файлы в зжатую папку
		FOR EACH lcFile IN this.Files
			this.oShell.NameSpace(FULLPATH(this.ZipFolder)).CopyHere(m.lcFile)
		ENDFOR
		
		* и ожидаем, когда все они туда попадут... Только после этого мы можем вернуть управление и отослать письмо...
		* к сожалению по другому никак не проверить, что все фалы заархивированы...
		DO WHILE this.oShell.NameSpace(FULLPATH(this.ZipFolder)).Items.Count=this.Files.Count
			INKEY(this.ZipInterval)
		ENDDO
		this.oShell=.NULL.
	ENDPROC
	
	PROCEDURE Init
		this.Files=NEWOBJECT([FilesCollection])
	ENDPROC
ENDDEFINE

DEFINE CLASS FilesCollection AS Collection
	PROCEDURE AddFile
		LPARAMETERS tcFileName AS String
		IF NOT TYPE([this.Item(]+LOWER(m.tcFileName)+[)])=[U] THEN
			this.Remove(LOWER(m.tcFileName))
		ENDIF
		this.Add(FULLPATH(m.tcFileName),LOWER(m.tcFileName))
	ENDPROC
	
	PROCEDURE RemoveFile
		LPARAMETERS tcFileName AS String
		this.Remove(LOWER(m.tcFileName))
	ENDPROC
	
	PROCEDURE Clear
		LOCAL liIndex AS Integer
		FOR m.liIndex=1 TO this.Count
			this.Remove(1)
		ENDFOR
	ENDPROC
ENDDEFINE