set path to 'd:\test'

local oListener
oListener = createobject("rotateText")
oListener.ListenerType = 1
report form report1 preview object oListener

#define FRX_OBJCOD_PAGEHEADER 1 

DEFINE CLASS RotateText AS ReportListener
	IsInPageHeader = .F.
	
	procedure Init() 
		declare integer GdipRotateWorldTransform In GDIPlus.Dll integer graphics,single angle,integer enumMatrixOrder_order
		declare integer GdipTranslateWorldTransform In GDIPlus.Dll integer graphics,single dx,single dy,integer enumMatrixOrder_order
		declare integer GdipSaveGraphics IN GDIPlus.DLL integer graphics, integer @xx
		declare integer GdipRestoreGraphics IN GDIPlus.DLL integer graphics, integer xx
	endproc

	procedure BeforeBand(nBandObjCode, nFRXRecNo) 
		dodefault(nBandObjCode, nFRXRecNo)
		if  (nBandObjCode = FRX_OBJCOD_PAGEHEADER)
			THIS.IsInPageHeader = .T.
		endif  
	endproc 

	procedure AfterBand(nBandObjCode, nFRXRecNo)
		if (nBandObjCode = FRX_OBJCOD_PAGEHEADER)
			THIS.IsInPageHeader = .F.
		endif 
		DODEFAULT(nBandObjCode, nFRXRecNo)
	endproc 

	procedure Render(nFRXRecNo, nLeft, nTop, nWidth, nHeight,nObjectContinuationType, cContentsToBeRendered, GDIPlusImage) 
		local xx,x,y,z
		xx = 0

		if  this.IsInPageHeader
			* get appropriate versions of coords
			x = nLeft
			y = nTop

			* save the current state of the graphics handle
			z = GdipSaveGraphics(this.GDIPlusGraphics, @xx)

			* now move the 0,0 point to where we'd like it to be
			* so that when we rotate we're rotating around the
			* appropriate point 
			z = GdipTranslateWorldTransform(this.GDIPlusGraphics,x,y,0)
			* should check z here -- will be 0 if no error occurred

			* now change the angle at which the draw will occur
			z = GdipRotateWorldTransform(this.GDIPlusGraphics,-45,0)
			* should check z as above

			* restore the 0,0 point
			z = GdipTranslateWorldTransform(this.GDIPlusGraphics,-x,-y, 0)
			* should check z as above 
		endif

		* explicitly call the base class behavior when we are ready for it

		dodefault(nFRXRecNo, nLeft, nTop, nWidth, nHeight, nObjectContinuationType, cContentsToBeRendered, GDIPlusImage)

		* put back the state of the graphics handle 
		if this.IsInPageHeader
			GdipRestoreGraphics(this.GDIPlusGraphics, xx)
		endif 

		* don't let the base class behavior draw 
		* when and how it would otherwise do it 
		nodefault
	endproc 
enddefine