В курсоре t1_al имеются поля dnei, dn_per, op_pozakr.
Dnei – количество дней опозданий по переносу карточки и + по закрытию.
dn_per – количество дней опозданий по переносу.
op_pozakr - количество дней опозданий по закрытию.

Все поля необходимые для заполнения курсора t1_al, заполняются в курсоре perenosy
(поля в курсоре sum_per, sum_op_zakr, sum_nn)

Вопрос: Как данные из курсора perenosy записать в курсор t1_al

Allkay,

Кто будет участвовать огромное спасибо.

Как заполнить курсор, в принципе понятно, проблема в том, как сохранить данные, (Извлечь данные подсчета) из алгоритма подсчета. Ведь те данные, что мне нужны, существуют на этапе подсчета в алгоритме (Алгоритм подсчета дней) после окончания подсчета их нет (если остается то только последняя запись).
Для заполнения курсора t1_al, нужно, на этапе подсчета в курсоре perenosy, запоминать данные, чтобы по окончании подсчета из памяти заполнить t1_al.

Есть еще какие ни будь варианты?

SSn888,

Выход, я, кажется, нашел, и как не странно с помощью курсора.
Создал в начале алгоритма подсчета дней, курсор, затем в процессе подсчета количества дней заполнял новый курсор. На выходе получилось, мне нужный курсор t1_al, для заполнения отчета, и новый курсор заполненный данными. Осталось только заполнить курсор t1_al из нового курсора.
А что плохого в ворожении: поле = поле + х ?

SSn888,

SSn888 Спасибо за помощь, я как говорил нашел выход и поэтому не проверял форум.
А ответ вот какой он:

*Выбор исходных данных (Основной курсор)
SELECT Pointtask.pointnumb, Pointtask.pointsod, Pointtask.dateout, ;
{..} as datenew, Pointtask.datefact, Pointtask.datecansel, Pointtask.datemarke, ;
000000 as dnei, 000000 as dn_per, 000000 as op_pozakr, ;
(ALLTRIM(pointtask.regnumb)+'('+ALLTRIM(pointtask.pointnumb)+')') as regn, ;
IIF(EMPTY(pointtask.datenew), pointtask.dateout, pointtask.datenew) as d_n, ;
IIF(EMPTY(pointtask.datefact) OR pointtask.datefact>datt_ok, datt_ok, pointtask.datemarke) as d_mkk, ;
Ispleader.fio as fiomark, Abonent.fio as fioreg ;
FROM bduaski!Pointtask ;
LEFT OUTER JOIN bduaski!ispleader ;
ON Pointtask.tabmark = Ispleader.tabel ;
LEFT OUTER JOIN bduaski!abonent ;
ON Pointtask.tabreg = Abonent.tabel ;
WHERE Pointtask.regnumb = lcRegNumb ;
UNION ;
SELECT Pointmove.pointnumb, " " as pointsod, {^2199.12.31} as dateout,;
Pointmove.datenew, {..} as datefact, {..} as datecansel, Pointmove.datemarke, ;
000000 as dnei, 000000 as dn_per, 000000 as op_pozakr, ;
" " as regn, {..} as d_n, {..} as d_mkk, ;
Ispleader.fio as fiomark, Abonent.fio as fioreg ;
FROM bduaski!Pointmove ;
LEFT OUTER JOIN bduaski!ispleader ;
ON Pointmove.tabmark = Ispleader.tabel ;
LEFT OUTER JOIN bduaski!abonent ;
ON Pointmove.tabreg = Abonent.tabel ;
WHERE Pointmove.regnumb = lcRegNumb ;
ORDER BY 1,3 INTO CURSOR t1_al READWRITE

*Создание курсора
CREATE CURSOR pointtask2 (pointnumb C(9), datenew D(8), datemarke D(8), kol_dn_op N(10), kol_dn_oprab N(10), sum_kol_dn_oprab N(10))
*Алгоритм подсчёта дней
SELECT t1_al
SCAN
*Селект собирающий все переносы по текущей карте
SELECT pointmove.pointnumb, pointmove.datenew, pointmove.datemarke, 000000 as kol_dn_op, 000000 as kol_dn_oprab, 000000 as sum_kol_dn_oprab ;
FROM pointmove WHERE ALLTRIM(pointmove.regnumb)+'('+ALLTRIM(pointmove.pointnumb)+')'=t1_al.regn INTO CURSOR perenosy READWRITE ORDER BY 1,3

SELECT perenosy
GO TOP
*Подсчёт общего числа переносов
kol_per=RECCOUNT()
*Подсчёт Опоздания по переносам
op_per=0
*Подсчёт Опоздания по закрытию, или не закрыта а должна
op_zakr=0
*Если есть переносы, выполняется:
IF kol_per>0
*Запоминаем дату када должен был быть первый перенос (дата первого переноса это -- дата выполнения)
dat_perper = t1_al.dateout
FOR i=1 TO kol_per
*Если есть опоздания, т.е. дата выполнения меньше даты отметки (SKIP 1)
IF dat_perper < perenosy.datemarke
*Считаем кол-во дней опоздания
nn = perenosy.datemarke - (dat_perper)
REPLACE perenosy.kol_dn_op WITH nn
*Выключен подсчёт рабочих дней
nn = nn-3
*Если nn < 0 значит опозданий нет
IF nn < 0
nn = 0
ENDIF
*Проссумировали дни опоздания
op_per = op_per + nn
REPLACE perenosy.kol_dn_oprab WITH nn
REPLACE perenosy.sum_kol_dn_oprab WITH op_per

*Заполнение курсора данными из другого курсора
*SELECT perenosy
*GO TOP
*IF !EOF()
INSERT INTO Pointtask2 (pointnumb, datenew, datemarke, kol_dn_op, kol_dn_oprab, sum_kol_dn_oprab);
VALUES (perenosy.pointnumb, perenosy.datenew, perenosy.datemarke, perenosy.kol_dn_op, perenosy.kol_dn_oprab, perenosy.sum_kol_dn_oprab)
*ENDIF
ENDIF
*Присвоение (следующего) начального значения для даты переноса
dat_perper = perenosy.datenew
*Перемещаемся на след по времени перенос
SKIP
*Выход из цикла если больше нет переносов
ENDFOR
ENDIF
*Были или нет переносы,считаем колво дней опозданий с даты начала подсчёта(dateout или datenew <соответствует последнему переносу>)
nn = t1_al.d_mkk - (t1_al.d_n)
nn = nn - 3
IF nn < 0
nn = 0
ENDIF
op_zakr = op_zakr + nn
*Заполняем главную таблицу
SELECT t1_al
*Заносим подсчитанные дни опоздания ( t1_al -- заполняется во время выполнения цикла )
REPLACE t1_al.dnei WITH op_per + op_zakr, t1_al.dn_per WITH op_per, t1_al.op_pozakr WITH nn
ENDSCAN

*Заполнение курсора t1_al курсором Pointtask2*
SELECT t1_al.pointnumb, t1_al.pointsod, t1_al.dateout, ;
t1_al.datenew, t1_al.datefact, t1_al.datecansel, t1_al.datemarke, ;
t1_al.dnei, t1_al.dn_per, t1_al.op_pozakr, ;
t1_al.fiomark, t1_al.fioreg, ;
Pointtask2.kol_dn_op, Pointtask2.kol_dn_oprab, Pointtask2.sum_kol_dn_oprab ;
FROM t1_al ;
LEFT OUTER JOIN Pointtask2 ;
ON t1_al.pointnumb=Pointtask2.pointnumb AND t1_al.datenew=Pointtask2.datenew ;
ORDER BY 1,3 INTO CURSOR expPoint READWRITE

*Последний селект для заполнения отчета*
SELECT expPoint.pointnumb, expPoint.pointsod, ;
IIF(expPoint.dateout={^2199.12.31},{..},expPoint.dateout) as dateout, ;
expPoint.datenew, expPoint.datefact, expPoint.datecansel, expPoint.datemarke, ;
expPoint.dnei,;
IIF(expPoint.dn_per<expPoint.kol_dn_oprab, expPoint.kol_dn_oprab, expPoint.dn_per) as dn_per, ;
expPoint.op_pozakr, ;
expPoint.fiomark, expPoint.fioreg ;
FROM expPoint ;
INTO CURSOR expert READWRITE