* Настройка, предотвращающая возникновения запроса в случае создания таблицы с именем уже существующей таблицы
* Необходимо молча удалить ранее существующую таблицу и создать новую с тем же именем в том же месте
set safety off

* Цикл, перебирающий найденные таблицы
For i =  1  to ADir(arDbfs, 'E:\temp\kaf????.dbf')

	* Для отладки и чтобы контролировать процесс
	?arDbfs[i, 1 ]

	* Открываем очередную таблицу, задавая ей фиксированный алиас
	USE 'E:\Temp\'+arDbfs[i, 1 ] EXCLUSIVE alias Tab1

	* Копируем содержимое таблицы во временную таблицу с фиксированным именем
	* Можно было бы использовать COPY TO, но Select-SQL - более универсальное решение
	select PR, GOD, FO, FAKULT, SPEC, S_FAK, SPK, KURS, KOLST, OPLP, OPLX, KOLGR, KOLPGR, SEM, PG, NED;
	, PPNAME, KBLOK, NBLOK, KAF, PRED, DISZIP, NKAF, LEK, LAB, PRA, IND_RUK, EKZ, ZA, KUR, KONT, GOS;
	, H_LEK, H_LAB, H_PRA, H_IND_RUK, H_ZA, H_EKZ, H_GOS, H_KONS, H_KONTR, H_KUR, H_DIPL_RUK, H_DIPL_REZ;
	, H_PRA_U, H_PRA_P, H_ASP_RUK, H_SOISK_RU, H_EKZV, H_RUK, H_FDP, H_OTHER, H_VSE, H_VSEP, H_VSEX, KPBLOK;
	from Tab1  into dbf tCursor

	* Закрываем как исходную таблицу, так и ее копию
	close all

	* Открываем таблицу с образцовой структурой
	use TMP3

	* На основе образцовой таблицы создаем таблицу с именем очередной таблицы, 
	* но со структурой, совпадающей со структурой образцовой таблицы и пустую
	* При этом, ранее существовавшая таблица с тем же именем уничтожается
	copy stru to ('E:\Temp\'+arDbfs[i, 1 ])

	* Закрываем все открытые таблицы
	close all

	* Открываем только что созданную таблицу с новой структурой, но пустую
	USE 'E:\Temp\'+arDbfs[i, 1 ]

	* Копируем в нее данные из копии исходной таблицы
	APPEND FROM E:\Temp\tCursor.DBF

	* Закрываем все открытые таблицы
	close all

next

create table test (f1 C(10))
select f1, 0000.0 as f2 from test into table test2