***********************************
* Генератор уникальных ключей
***********************************
* после упаковки делать delete file *.id
Func NewId
Para tcDbfName

local lnRetId, lcIdVar, lnF, lcS, lnPos, lcIdField, lcFileId, lcSe, lnId, lnF, lnStop, lcFVar
* Получаем текущее Id для таблицы tcDbfName
lcIdVar = 'gn' + tcDbfName + 'NewId'
if type('plQuickId') = 'L' and plQuickId and type(lcIdVar) = 'N'
	* Режим быстрого монопольного получения Id
	lnRetId = &lcIdVar
	&lcIdVar = &lcIdVar +  1 
else
	* Если до этого был "быстрый режим", то закрываем файлы *.Id
	if type('gcTableList') = 'C' and !(type('plQuickId') = 'L' and plQuickId)
		do while !empty(gcTableList)
			lnPos = at(';', gcTableList)
			if lnPos =  0 
				lcS = gcTableList
				gcTableList = ''
			else
				lcS = left(gcTableList, lnPos -  1 )
				gcTableList = substr(gcTableList, lnPos +  1 )
			endif
			lcVar = 'gn' + lcS + 'NewId'
			if type(lcVar) = 'N'
				release &lcVar
			endif
			lcVar = 'gn' + lcS + 'File'
			if type(lcVar) = 'N'
				fclose(&lcVar)
				release &lcVar
			endif
			
		enddo
		release gcTableList
	endif
	* Режим сетевого получения Id
	lcFileId = fullpath(tcDbfName + '.dbf')
	if !file(lcFileId)
		MessageBox('Не найден файл ' + UPPER(tcDbfName) + ".DBF",  16 , 'ОШИБКА')
		quit
	endif
	lcFileId = left(lcFileId, rat('.', lcFileId)) + 'id'
	if file(lcFileId)
		* Читаем текущее значение
		lnStop = seconds() +  20 
		Do while .t.
			lnF = fopen(lcFileId,  12 )
			If lnF <  0 
				If lnStop < seconds()
					If messagebox("Не могу открыть файл " + lcFileId + chr( 13 ) + "Попробовать еще ?",  32  +  4 , "Функция NEW_ID()") =  6 
						lnStop=seconds() +  20 
					Else
						Quit
					Endif
				Endif
				Inkey( 0 . 1 )
			Else
				Exit
			Endif
		Enddo
		lnRetId = val(fgets(lnF))
		Fseek(lnF,  0 ,  0 )
	else
		lnRetId =  0 
		lnF = fcreate(lcFileId)
		if(lnF <  0 )
			MessageBox('Не удалось создать файл ' + lcFileId,  16 , 'ОШИБКА')
			quit
		endif
	endif

	If lnRetId =  0 
		* Если нет файла с Id или в нет  0 , то рассчтываем Max(Id) +  1 
		lcIdField = 'n' + tcDbfName + 'id'
		lcSe = str(sele(), 2 )
		select max(&lcIdField) as nId from &tcDbfName into cursor calc_id
		lnRetId = calc_id.nId +  1 
		Use in calc_id
		Sele &lcSe
	endif
	* Сохраняем результат для следующего запроса
	if type('plQuickId') = 'L' and plQuickId
		* Быстрое монопольное считывание
		if type(lcIdVar) = 'U'
			public &lcIdVar
		endif
		&lcIdVar = lnRetId +  1 
		Fputs(lnF, '0') && в файл сохраняем  0  для последующего расчета
		* Сохраняем хэндл файла
		if type('gcTableList') = 'U'
			public gcTableList
			gcTableList = tcDbfName
		else
			gcTableList = gcTableList + ';' + tcDbfName
		endif
		lcFVar = 'gn' + tcDbfName + 'File'
		if type(lcFVar) = 'U'
			public &lcFVar
		endif
		&lcFVar = lnF
	else
		* Обычное считывание. Сохраняем в файл
		Fputs(lnF, alltrim(str(lnRetId +  1 )))
		fclose(lnF)
	endif
endif
Return lnRetId